*temp struggle 1
*temp variable false
*temp hostile false
*temp bristle false
*temp goaway false
*temp ari 1
*temp questions 0
*temp odds 0

*if expressive < 35
    *set variable true

A blow clubs you straight in the back of the head. Two more in almost the same instant. You spill to the ground, attempting to raise your hands in defence.

It's futile. A kick slams into your ribs. A second. A third.

A three step rhythm. You know what's happening. You know [i]who[/i] is happening.

Your assailant grabs a fistful of your shirt and hauls you bodily to your feet before pinning you against the nearest wall. A forearm grinds into your throat, choking you.

Now you're facing your attacker, but you could have described him before ever seeing him. He's so very familiar.

Deep brown skin. Eyes so dark they're almost black. Shaven head. A grin gleaming with wild malice.

"Hello, little ${mc_sibling}."

Little ${mc_sibling}. How many times have you heard that?

*choice
    #Struggle.
        *set struggle 1
        *set seethe +1
        You grip at the arm pressed into your throat. It's like an iron bar, unyielding and unmoving against your fingers.
        
        "Stay still," growls Catalyst.
        
        There's no option but to comply.
        
    #Plead.
        *set struggle 2
        *set break +1
        "chk—chk—" You lack the air to choke so much as a word from your mouth.
        
        "Shut up," growls Catalyst.
        
        There's no option but to comply.
    #Submit.
        *set loyal +1
        *set struggle 3
        There's nothing you can do. You go limp.
        
        "That's a good ${mc_boy}," purrs Catalyst.
        
        You don't let yourself react.

He lessens the pressure on your windpipe, just enough to allow you to breathe. Catalyst isn't tall—@{mc_height DUMMY|bigger than you mostly because you're tiny|not significantly taller than you|only around your height|noticeably shorter than you|considerably shorter than you}—but he's muscular, with broad shoulders and massive biceps. He immediately puts the power of his frame to use, grabbing you by the collar and dragging you into a nearby alleyway.

You scarcely have time to react before you're back up against the wall, a rain of punches slamming into your abdomen and driving you into the unforgiving brick. One two three. One two three. One two three. One two three.
*choice
    *selectable_if ((seethe >= break) and (seethe >= loyal)) #I endure the blows, and I mask the hatred from my face.
        *set coven_history 3
        *set defiance 3
        Fighting back won't help. This you know.
        
        So instead you'll bide your time, neither forgetting nor forgiving, and silently add each new humiliation and beating to the list.
        
        One day, there will be payback.

    *selectable_if ((break >= seethe) and (break >= loyal)) #I flinch from the beating, cowering in surrender.
        *set coven_history 1
        *set defiance 0
        Once upon a time you fought. Before he broke you. Before they broke you.
        
        Even the fiercest resistance can't hold out forever. Not without respite or hope of rescue.
        
        Whatever guttering flame of defiance you held is long since extinguished. Now, little more than ash remains.

    *selectable_if ((loyal >= seethe) and (loyal >= break)) #I lower my head in deference. He'll stop soon.
        *set coven_history 2
        *set defiance 1
        This is the price of obedience. You've endured plenty of beatings to earn your place.
        
        It's just what Catalyst does, and he's far further up the pecking order.
        
        You can handle some pain; you have to. It's the least that's expected of you.
        
*if mc_health = 1
    *set mc_health 2

*if recovery = 2
    *set recovery 3
    
*set injurydesc 6   
*page_break One two three
Catalyst delivers one final punch to your gut. A heartbeat later, two more impacts rock your body.

He retracts his fist, leaving you to slowly slide to the ground, clutching your stomach. He's still grinning. All teeth.

*if coven_history = 1
    @{struggle "Fun seeing you fight a little, Paradigm. Reminds me of the old days. Before you learned."|"Bet you were trying to beg, weren't you? I remember when you were so defiant."|"I remember when you'd have fought back. Almost miss those days, Paradigm."}
    
    You avoid his gaze. @{struggle Stupid. Why did you resist? He probably hit you more just because of that.|There's no sting of pride. You lost that long ago.|Yeah. You remember too. And it brought nothing but pain.}

*elseif coven_history = 2
    @{struggle "Not like you to struggle, Paradigm. Better not be getting any ideas now you're out in the big wide world."|"Not sure if you were trying to beg. Thought you knew better."|"Rolling over as always, little ${mc_sibling}. You're so well behaved."}
    
    You lock your gaze at somewhere around his ankles. @{struggle Fighting back was probably muscle memory from yesterday. You should have known better. He probably hit you more just because of that.|You couldn't help it. Sometimes the instinct to call for mercy slips out.|You're numb to the taunt. What does it matter if he mocks you?}
*else
    @{struggle "Was that a little fight, Paradigm? Wonder about you sometimes."|"Were you trying to beg? Always fun to see you crack a little, Paradigm."|"It's almost boring how you just stand there and take it, Paradigm."}
    
    You lift your gaze to his momentarily, and then look away. Can't go looking too defiant now. @{struggle Probably shouldn't have fought back, but even you have your limits.|You're kind of pissed with yourself for letting him get that out of you, but whatever. Hopefully it keeps him complacent.|You keep your seething resentment on the inside. Letting him hit you usually gets the ordeal over with faster, but it rankles to endure his taunting.}
    
"Anyway, Hypothesis wants you for some reason, so I'm taking your sorry ass back to base."

Back to base? Your heartbeat quickens. Did you screw up somehow? @{coven_history Are they recalling you for punishment?|Have you displeased Hypothesis?|You haven't even acted on any of your thoughts of resistance!}

@{diming Wait. Surely they can't already know about you using $!{mask} as a name. Unless the earbud really is eavesdropping.|}

"Move."
*page_break Get up before he hits you again.

You haul yourself to your feet against your body's protests, acutely aware of Catalyst's impatient glare. 

*if guts < 30
    For a moment you falter, sagging back into the wall. You have to brace yourself, pushing off against the brick and swaying upright.
    
*else
    For a moment you sway, nearly sagging back into the wall, but you clench your fists and will strength into your legs.
    
Catalyst smirks sardonically. "Toughen up." He walks to the mouth of the alleyway. "You know what happens if you fall behind."

He doesn't wait for you. Not that you'd expect him to. You force through the aches of your freshly forming bruises @{recovery ||and renewed pains of your unhealed injuries} and get moving. Catalyst is already several strides ahead. You grit your teeth. Keeping pace with him won't be easy.
*page_break
    
Walking with Catalyst could scarcely be more different than your earlier stroll accompanying Dion and Mallory. Catalyst forges ahead like a walking tank. Anyone unfortunate enough to get in his way is shouldered roughly aside. You're left to hurry along in his wake, scurrying past shocked faces and angry remonstrations. Though it's your first time seeing Catalyst interact with the outside world, you're far from surprised.

*if ((walkfeel = 1) and (coven_history = 3))
    As for the walk itself, well, you suppose the bitter tinge persists. Yeah. This is exactly why you couldn't actually enjoy the experience. The truth of your situation.
    
*elseif ((walkfeel = 4) and (coven_history < 3))
    As for the walk itself, well, you suppose the emptiness is familiar enough. @{coven_history Numbing yourself before lessens the pain when you come back to reality.|No point feeling anything before when this is your normal.|DUMMY}

*else
    As for the walk itself, @{walkfeel the bitterness is absent, giving way to your focus on keeping up. Giving way to the knowledge of how dangerous it is to feel such a feeling.|there's no room for melancholy. This is your reality.|there's no sense of nostalgia, no feeling of comfort. Follow, or face the consequences.|the numbness is thawing as you're reminded of everything you hate about your situation.}
    
Catalyst isn't too far ahead, which is just as well. Although there are more people around now than on the street where he first jumped you, if Catalyst decides he wants to come in for another round, you doubt that anything short of a hero or a DPR squad would give him pause.
*choice
    #Psychopath.
        @{coven_history Catalyst takes delight in hurting. And in hurting you specifically. You involuntarily shudder, overtaken in a flood of memories, ghostly echoes of blow after blow slamming into your body. That quells your anger towards him in a hurry. You can't think this way. It's dangerous.|Dealing with Catalyst is an unavoidable part of life. Nobody said that you have to like him.| Catalyst is a sadist, pure and simple. If it wouldn't bring the wrath of the heroes down on him, you don't doubt that he'd happily maim these bystanders just for daring to be in his path.}
        
    #So I'd better tough it out.
        @{coven_history Avoiding Catalyst's ire is an ingrained survival instinct. A clammy claw of dread grips you at the thought of provoking another attack.|Catalyst is acting on orders from the top, so delaying the trip by ticking him off could have further consequences. Best to keep your head down.|Catalyst barely needs an excuse to go after you at the best of times, you can't afford to hand him one.}
        
    #If only I could see Catalyst against the Hounds.
        @{coven_history It's a mutinous, dangerous thought, one you quell with an urgency bordering on panic. You can't. You [i]can't.[/i] Not even in daydreams.|It's a privately mutinous thought, one which you dare hold for only a moment. You couldn't possibly be a neutral observer to such a conflict. …Not unless ordered.|It's a thought to savour, to put a brief and passing smile on your face. Catalyst fighting Surpass? Yeah. You'd enjoy spectating that.}
       
       
Catalyst continues plowing forward for another few blocks. Just as your stamina begins to fail you, he stops. You've reached your destination. He glances back, face turning almost disappointed when he finds you're still relatively close by. 

The new Coven base has little in common with the abandoned compound of a half decade ago. The building is a modest three storey office space, cosily situated on a little urban islet. There's even a small private parking lot. All perfectly unassuming. This is only the third time you've seen it from the outside.

Catalyst marches to the entrance, stopping for the briefest moment to slap a keycard onto a reader by the door before hurling it open. You hurry to pass through in his wake; he's not going to hold it for you and if he has to let you in, he'll most certainly reclaim the debt in more bruises. Just in time, you slide on through, finding yourself in a nondescript lobby that serves as HQ's actual security. Hypothesis wouldn't trust to anything so pedestrian as a locked door. Not any more.

*page_break Not since...
A pale figure with sandy blonde hair and smart casual attire is seated behind a desk, attention far more preoccupied by a novel than the row of monitors in front of them.

"Hello, Catalyst," they say, not looking up. Their voice is calm and smooth. @{walkiechat You'll never forget that first time you heard it, emerging from a hidden walkie talkie. That should have been your warning to run. You should have known something sinister was happening.|}

"Let us in," Catalyst growls. He hates Lullaby almost as much as he hates you. Difference being he can't physically attack them.

Lullaby finally glances up from their book. "Ah, Paradigm too." Their mouth twitches up at the corners. "Good afternoon." @{coven_history You can barely meet their gaze for a moment, quickly looking away.|You deferentially drop your gaze, meaning you don't have to meet theirs.|Meeting their gaze is uncomfortable, and you have to look away.} Dark eyes. Nothing behind them.

"Let. Us. In," Catalyst repeats, almost snarling.

"Patience is a virtue," says Lullaby, and then there's an electronic chime. "Go ahead."

Catalyst stomps by them without acknowledgement, and you follow him past the desk and into the newly-unlocked elevator. Catalyst aggressively slams the button for the third floor. As the elevator doors slide closed, Lullaby is already back to reading.

In those close confines you can feel the rage pouring from Catalyst. His fists are clenched, tight enough to tremble.
*fake_choice
    #Keep calm. Everything's fine.
        *set expressive %- 10
        You try to slow your breathing. Instead you end up stopping it entirely. There's a panicked moment where you forget how to restart.
        
        Calm. As if you could ever be calm with Catalyst around.
        
    #Take a slow and measured step, putting as much distance between us as possible.
        *set instinctive %- 10
        You regret the movement almost as soon as you make it, certain that you'll draw Catalyst's attention.
        
        By some miracle, he doesn't notice, eyes fixed on the elevator doors.
        
        Why did you do that?
        
    #Be ready to react the second he tries anything.
        *set instinctive %+ 10
        You subtly shift your posture, psyching yourself up for… for what, exactly?
        
        Self defence? You shouldn't be thinking self defence.
        
    #A joke will defuse the tension!
        *set expressive %+ 10
        You open your mouth, but no sound emerges, @{coven_history fear|fear|self-preservation instincts} paralysing your tongue.
        
        Joking around. With Catalyst. 
        
        You must be crazy. 

A week away from here has disrupted the rhythm of survival. Talking with outsiders. Time to yourself. Not spending every waking moment looking over your shoulder. It's all interfering with the lessons of the past half decade. Lessons you can't afford to let slip.

You can't lose what little progress you've earned. @{coven_history Y-you couldn't handle it.|You've done everything they asked.|You've endured so much.}

The elevator comes to a halt. You suppress the urge to flee, exiting behind Catalyst. You're barely out of there before he turns and cuffs you around the head.

Two. Three. The extra strikes rattle your skull. "I'm not babysitting you, little ${mc_sibling}. Go see Hypothesis." With that he stalks off.

All you feel is relief. If you'd truly incurred the Coven's wrath, Catalyst wouldn't just walk away from you. He'd be dragging you straight to Hypothesis's door. That, then, means the earlier attack was little more than a Catalyst style hello. Nothing strange there; he can barely go five minutes in your presence without taking a swing.

You know why. You just don't like thinking about it.
*fake_choice
    #Dwelling on that night hurts too much.
        Another puzzle piece of the pain from the night you lost everything. @{brokenheart Everything.|Everything.|Everything.|Everything.|}
        
        It's all too easy to send yourself into a tailspin of regret and grief.
        
    #The memories are entangled with too many beatings.
        Keeping Catalyst in your mind for any length of time means bringing to life all the days and weeks and months at his tender mercies.
        
        His knuckles are tattooed on you, body and brain.
        
    #There's no point. Knowing doesn't stop him.
        Understanding the motive might be how a detective gets their man, but there's no benefit to you.
        
        You can't bargain, you can't persuade, and you can't change the past.
        
        
Five years ago, Catalyst was supposed to keep intruders out of the compound and the hidden basement below. He failed, and that failure allowed you and your friends to descend into the jaws of death.

You don't think you'll ever know what kept him from his post that night. It barely matters. You're a walking reminder of his screw up. A screw up that destroyed your life.
*fake_choice
    #I need to stop.
        You have to get this out of your head. Now. This path leads to nothing and nowhere.
        
        And yet it keeps flooding in, faster and faster. If he'd done his job. If you'd picked a different evening. If you'd listened to Shauna's misgivings.
        
    #And isn't that a fucked up kind of ironic?
        He hates you because he made a mistake that cost [i]you[/i] everything.
        
        If Catalyst had done his job, he would have spared himself, what, a little loss of face?
        
        If Catalyst had done his job, you…
        
    #It's his fault. All of it.
        *set defiance +1
        All Catalyst needed to do was scare you and AdVenture away, and everything would be different. You'd be living as an ordinary person. Maybe you'd still be recording urbex with the others. 
        
        No powers. No supervillainy. No dead friends. @{dating No lost love.|}
        
You'd still be you.        
        
@{coven_history No! You reject the thought violently. No. No, no, no. You can't do this again. You know what happens if you do.|No! You wrestle the thought into submission. That's dead and buried and gone.|With reluctance, you push the thought away. Here in the Coven's heart isn't the time or place.}

As you shake it off, you realise that you've been standing by the elevator for too long. You need to move.

Hypothesis doesn't like to wait.
*page_break
Your destination lies through a door on the opposite side of the office that is the third floor. It really does resemble an office too, with two neat banks of desks arrayed alongside the windows and a kitchenette tucked into one corner. A pair of the desks are in use, their occupants busily typing away. Two 'coworkers' talk over coffee in the kitchen. Perfectly normal people enjoying a perfectly normal working day.

You know better.

Swiftly, you cross the room. Someone hails you with a call of "Hi Dime!" and you lift a hand to acknowledge them as you keep moving—no time for chatter. Soon enough, you're out into the corridor, and then it's just a few short steps before you're in front of a familiar door. Dark, burnished wood.

You swallow hard. Reach out to knock, pretending not to notice the shake in your hand.

"It's open!"

That voice. @{coven_history There's no kidding yourself about the tremors now. Not when your whole body is atremble.|Ingrained obedience hits you like a truck, and you have to force your head not to bow before even entering the room.|A mixture of fury and dread courses through your veins.}

*page_break Step inside.

The room could belong to a science teacher. There are bookshelves loaded with chemistry and power theory. A model skeleton in front of an anatomical chart. A periodic table on the wall bordered by an annotated map of Alderbrook. A heavy oak desk, surface occupied with papers, a flask of viscous blue liquid, a human hand preserved in a jar.

And seated behind the desk, looking up at your entry. Hypothesis.

"Paradigm. Good to see you."

He's in perhaps his fifties, with a few lines in his fair-skinned face. His hair is dark and short, greying almost to white at the temples and throughout his full and trimmed beard. Bright blue eyes regard you from behind a pair of spectacles. He's wearing a button-up shirt under one of his innumerable sweater vests.

@{coven_history Your throat constricts, stealing your words away.|You drop your eyes instantly.|You've lost count of your fantasies of smashing those glasses straight into his face.}

"How have you been?" Hypothesis continues genially, as if you're a friend and not his @{coven_history servant|subordinate|captive}.
*fake_choice
    #Mimic small talk.
        *set expressive %+ 5
        "I'm… well," you say. "What…what about you?"
        
        Your words are halting. Awkward. @{coven_history You can't help but second guess each as it emerges, analysing for anything that will invite reprisal.|Is this what he wants? You can't tell, petrified of violating an unknown order.|Despite your broiling emotions, you're daunted in his presence, the slender flame of your resolve all aflicker.}
        
        "I'm quite alright Paradigm, thank you for asking." There's a note of amusement in his voice.
        
    #Say as little as possible.
        *set expressive %- 5
        "Fine," you mumble, fixing your attention to the front of the desk. @{coven_history The less you say, the less likely it is you'll cross some unknown line.|You're here to listen, not to talk.|The sooner this is over with the better. You're already suffocating.}
        
        "Excellent," he replies.
        
    #Autopilot.
        "I'm well, thank you," you recite mechanically. @{coven_history Independence invites punishment. Say what's expected and nothing more.|Deference comes naturally. He wants to go through the motions, so you will too.|Setting your brain on neutral is the safest bet for navigating these interactions.} 
        
        "Excellent," he replies.
        
You bob your head, the picture of compliance. @{coven_history It's all you can be anymore. Anything else is...|It's not your place to advance the conversation.|Hollow yourself out. Show no signs of dissent. Wait. Wait, for as long as it takes.}

"You're wondering why I invited you here, I imagine."
*fake_choice
    *selectable_if (expressive = 100) #"Surprise party?"
        Hey! You shouldn't be here!
    *selectable_if (instinctive = 100) #"Not particularly."
        Hey! You shouldn't be here!
    #Nod.
        Hypothesis likes to build up to a point. You shouldn't interrupt his flow.

"Earlier today I instructed Gremlink to scrape the data from surveillance cameras in the vicinity of the Zone," Hypothesis explains. Gremlink is the resident tech expert, an augmented freelancer who happens to be the creator of your earbud. "While cataloguing her findings, she uncovered something rather interesting. Take a look at this."

Hypothesis slides a photograph across the surface of his desk, swivelling it to face you. As grainy as the picture is, the shattered destruction of the Zone is unmistakable. Deducing that Hypothesis wouldn't just show you a random photo of the Zone, you study it more intently. After a moment, you manage to barely make out two figures picking their way through the rubble, and recognition hits immediately. "That's…"

"Architect and Wyrd, correct." Hypothesis steeples his fingers. "The image you see was captured four days ago. As a matter of fact, it's the only image of the pair; all the remaining footage has been doctored. Lo and behold, my suspicions are confirmed." A sly, self-satisfied smile curves his lips. "Attempting to sneak about the city under my nose? I think not."

@{coven_history You attempt not to shiver. The step by step dissection, complete with verbal flourishes. It's so familiar. Too familiar.|You just listen, caught up in the flourishes of the explanation. He's always three steps ahead.|You maintain an attentive posture, feigning interest. He does love the sound of his own voice, doesn't he? If he knew all along, he wouldn't have sent you out.}
*page_break

Hypothesis goes on. "Paradigm, you're to continue as before. Find out everything you can about their plans in Alderbrook. If the Zone comes up in any capacity and especially if they intend to venture there again, report it as soon as possible. Face to face. Furthermore, hacking DPR security is beyond your standard street villains. I'm quite certain those two are using pseudonyms. Uncovering their true identities is your secondary objective. Am I understood?"

@{coven_history "Yessir."|"You can count on me."|You nod.}

"Excellent. Dismissed."

@{coven_history You sag with relief.|You dip into a short bow.|Finally. You can't wait to leave.}

Though as you begin to turn away, something nags at you. Why were you recalled for what amounts to a minor update? You were already scoping out the group. Hypothesis already suspected that Architect and Wyrd had changed their masks before coming to Alderbrook. This briefing surely could have been delivered via your earbud.

Do you dare ask why it wasn't?
*choice
    #Yes.
        *set doubt_hypothesis +5
        
        *if (subterfuge > 33)
            *set coveninfo +1
            *set covenbud true
            Questioning Hypothesis directly sounds like a great way to have a very bad time very quickly, so the more subtle approach it is.
            
            "Before I go, sir…"
            
            "Oh yes?" You've caught his attention. Careful now.
            
            "I just want to say that bringing me back was smartly done. I could have been in a bad position to take a call."
            
            He's silent for a moment. Long enough that you fear you've erred terribly. At last though, his lip curls with an indulgent smile, the professor with the prized pupil. "Not quite, Paradigm."
            
            You tilt your head, inviting him to go on.
            
            *goto hypotalk
        *elseif ((instinctive > 70) or (guts >= 35))
            *set coveninfo +1
            *set covenbud true
            You don't give your mind the chance to second guess your mouth.
            
            "Wasn't it a gamble to send Catalyst to collect me? Control Group could have told me about this tomorrow."
        
            Hypothesis fixes you with a silent stare. A stare long enough that you fear you've erred terribly. At last though, he speaks. "Half correct, Paradigm. A gamble? Somewhat. Communicating this via the earbuds? Absolutely not."
            
            Heart hammering a hundred miles per hour, you don't trust yourself to speak. Instead, you tilt your head questioningly.
            
            *label hypotalk
            "While the earbuds are useful, they are not without flaws. Hence certain information is best kept from the airwaves, lest it be heard by unwelcome ears."
        
            Whoa. You've wondered about the restrictions on the use of your earbud before, but you never suspected a security risk.
        
            "Makes sense," you reply, mind buzzing with the implications of this new insight.
        
            "Of course it does. Run along, Paradigm." Hypothesis waves you away, and you know better than to push your luck. You head for the door.
            *goto onemorething
        *else
            You hesitate to speak, caught in two minds over how to broach the question. Asking directly seems like too great of a risk. However, you're also drawing a blank on how to manoeuvre him into an explanation.
            
            "Paradigm. I said dismissed."
            
            @{coven_history Oh no. Oh fuck.|Oh no. Oh dear.|Oh fuck. Shit.} You'd recognise the faint tones of irritation in his voice anywhere. Immediately beginning to panic, you blurt your thoughts out half-formed. "Sorry I just—I wasn't sure why you needed to see me."
            
            "Because I requested it. Go."
            
            You've pushed your luck and your nerve to their limits. You scamper for the door pronto.
            *goto onemorething
    #No.
        You can't envisage any insights that would be worth the price of admission. You're not chancing retaliation by asking questions of a man who does not brook dissent.
        
        Concluding your turn, you head for the door.
        *goto onemorething

*label onemorething
*page_break

Hypothesis speaks, freezing you in your tracks. "Oh, one last matter before you go, Paradigm." You swallow and glance back. He's regarding you over the top of his spectacles. "Be sure to collect your next dose of the formula from Control Group on the way out. Don't overindulge now. There's a good subject."

You nod, hurrying from the room.

Out in the corridor, the great weight on your chest lifts ever so slightly, no longer suffocating. @{coven_history The crashing fear ebbs, if only a little. If only temporarily.|No need to be on full alert for orders, taut as a bowstring. Ready to snap.|At times you wonder if he sees straight through you, indulging your petty notions of rebellion as an amusement, something he can snuff out whenever he so chooses.}
 
A moment of respite. Enough to turn the briefing over in your mind.
*choice
    #What does this mean about Architect and Wyrd?
        Again, it's nothing new that the pair probably aren't using their real identities, but villains and even heroes used to do that all the time back in the day, and you're sure that nothing has changed there. Sometimes an old mask becomes too linked to a gimmick, or to an embarrassing gaffe. Sometimes a parahuman is just looking for a fresh start. It's some level of suspicious that Architect and Wyrd showed up and started moving pieces around the board, but they wouldn't be the first villains to change their masks and try to make a splash in a new city.
        
        Hacking the DPR though, that takes serious guts and serious skills. One or both of them is harbouring some hidden depths, or else they've got a secret computer geek stashed away, which is suspicious in and of itself. Risking the full attention of the DPR for the sake of concealing a trip to the zone… what are they hiding?
        
    #What's so critical about the Zone?
        It's literally rubble and ruins. Year old rubble and ruins. Keeping a cordon around the area makes sense—especially for the DPR, since it's the only reason they can be in Alderbrook—but why make such a big thing about venturing into the wreckage? What could be the object of such a search?
        
        You don't have answers or even a solid guess for any of the questions. $!{cg} only gave you the basic rundown for the Zone; maybe you need to hit the books and find out more.
    #Does Hypothesis trust me?
        A million dollar question.
        
        On some level he must. He had the pick of the Coven for this task, and he chose you. Clearly, @{coven_history he's confident that he's ground the defiance out of you.|you've shown enough obedience that he thinks you're reliable.|you've done enough to make him believe in your loyalty. Or maybe he doesn't think you'll dare act. Maybe you don't.}
        
        However, the nature of your ties to Hypothesis renders absolute trust unnecessary. He can afford to treat this as an experiment.
        
        What else is new?
        
*page_break Time to move on.        

As you emerge back into the office, you spot that one of the kitchen dwellers has been replaced by a familiar curly-haired and olive-skinned figure, clad in a leather jacket and jeans. $!{cg}. She's short and lean, a compact bundle of muscle. Countless hours and countless bruises sparring with her can attest to that. @{fighting_style You're good, but $!{cg} taught you everything you know. |||} Presently, she's engaged in… well, conversation probably isn't the correct word.

"Let me know if you need help with any leads, okay?"

"Sure—" $!{cg} begins.

"My assignment's going great so I can lend a hand. You're not nervous, right?"

"No, I'm—" She tries.

"Great! There's no need to worry, though if you do get worried that's okay too."

"Right—"

"When I first went out, I was really really nervous—"

Buried under the verbal onslaught, $!{cg} catches sight of you and sends a desperate 'help me' look in your direction. @{cg_dislike The temptation to leave her to squirm for a minute or two is almost overwhelming. Unfortunately though, $!{cg}'s glance also gets the attention of her captor.|You should probably go and bail her out. Nobody deserves to be subjected to that.} The other half of the 'conversation', a chubby, shaven-headed person with very dark skin, follows $!{cg}'s eyes and zeros in on you with a toothy grin.

"Paradigm! Get over here!" They flag you down. Variable, or Airy, always seems to be in a perpetual state of @{variable over|}excitement.

@{coven_history Reluctantly you edge closer to them, your eyes hunting for signs of aggression. Variable's never attacked you before, but there's always a first time.|You've already taken a step towards them before you consciously register what they said.|You consider telling them to get lost, but decide that it's best not antagonise them when they're standing next to somebody you need to talk to.}

Variable is…
*choice
    #An absolute pain in the ass.
        *set ariattitude 1
        Variable constantly sticks their nose into your business, shredding what little privacy you get around here.
        
    #Just another face in the Coven.
        *set ariattitude 2
        There are only a couple of people here that you're required to interact with, and Variable isn't one of them.
                
    #Somewhere in the orbit of a friend.
        *set ariattitude 3
        *if (cg_dislike)
            *set ari 2
            Not an actual friend. You don't do friends here.
            
        *else
            *set ari 3
            Between Variable and $!{cg}, you're a social butterfly. Two pseudo friendships? Stop the damn presses.
            
            Neither of them are truly friends. The Coven doesn't do friendships.
            
        It's just nice to pretend a little.
        
    *selectable_if (coven_history = 3) #A useful tool to cultivate.
        *set ariattitude 4
        Variable is guileless and you've never known them to harbour an ulterior motive. By listening, nodding, prompting where appropriate, you've managed to learn from them a fair few things that strictly speaking you shouldn't know. Small morsels, true, but the information adds up.
        *fake_choice
            #I feel a little guilty using them like that.
                Variable isn't responsible for all that's happened to—all that's been [i]inflicted[/i] on you. They have a lot more in common with you than they do the likes of Hypothesis and Catalyst. Manipulating them leaves a sour taste in your mouth, but it's self-preservation.
                
            #It's nothing personal, just survival.
                Sometimes, moral scruples have to take a backseat. You need every possible advantage, and if that means interacting with Variable under false pretences, then that's just the way it is. Besides, all you do is let them run their mouth. If they spill something they shouldn't, that's their own fault.
                
            #There's some vindictive satisfaction in manipulating them.
                Variable's so eager to do the Coven's bidding, a lapdog through and through. Of course it feels good to pull the wool over their eyes; they're a loyal servant of the man holding your chains. Exploiting their enthusiasm is a tiny measure of revenge.
        
"Good to see you back. How's your assignment going? Mine's pretty swell—"

@{ariattitude Also they never, ever shut up.|Sometimes, though, that's of no benefit. Variable's company can be… persistent.|And there they go. You can find a measure of comfort in the familiar rhythm of their chatter.|And they're straight into the standard verbal flood. You prepare to sift through the tide for the useful parts.}

"Airy," $!{cg} interrupts. "I need to talk to Dime. Alone."

Variable halts mid-sentence. That had the cadence of an order, and since $!{cg} has seniority on them, deference is instant. @{ariattitude If only you could stop them so easily.|What a relief.|Ah. So much for the comfort.|So much for the flood.} "Okay, sure, no problem!"

*if observation >= 35
    They hurry off. $!{cg} turns to you, her expression the studious kind of blank that only happens through conscious effort. If you're not mistaken, she's quietly furious.
    
*else
    They hurry off. $!{cg} turns to you, her expression flat and blank. You have no idea what she's thinking.
*choice
    *if (observation >= 35) #"Everything alright?" Angry $!{cg} is uncommon.
        *set rel_cg +2
        @{cg_dislike Her eyebrows momentarily rise, though she quickly schools her expression. "You checking in on me?"|She sighs. "Too sharp for your own good, Dime."}
        
        @{cg_dislike You shrug a little. Maybe, if you feel like it.|}
        
        *if expressive > 55
            @{cg_dislike |You smile slightly. "Maybe."}
            
        *else
            @{cg_dislike |You glance away, a little bashful.}
            
        "Anyway…" $!{cg} continues. "There's been a change of plans, and Hypothesis has given me a field assignment. We won't be able to check in daily like we intended. I'll let you know once I put together a different system."
        *goto usual
    *if (observation >= 35) #Don't say anything. Angry $!{cg} is uncommon and [i]explosive[/i].
        *set instinctive - 2
        @{coven_history You swallow, nerves jangling. She's mad, and wants to talk to you alone. Already you're bracing for the worst.|You'd prefer not to get on her bad side. Nor the bad side of anyone else who could have got her in this mood.|When strong emotions are in play around the Coven, keeping your head down is usually the best policy.}
        
        Realising that you're not going to speak, $!{cg} breaks the silence. "Hypothesis has given me a field assignment," she tells you, voice as carefully emotionless as her face. "We won't be able to check in each morning."
        *goto usual
    #"What is it?" Hopefully sending Airy away isn't a sign of something serious.
        *set instinctive +2
        @{coven_history You're on edge already.|Problems for $!{cg} might mean problems for the Coven.|Aren't you already balancing enough plates?}
        
    #"I'm supposed to get Juice from you." Business first.
        *set instinctive + 3
        *set rel_cg -2
        "In a minute, Dime," she replies tersely.
        
        @{coven_history "I'm sorry," you say reflexively.|"Of course," you say automatically.|"Sure," you say.} Nevermind.
        
    *if (observation < 35) #Wait for her to speak.
        *set instinctive - 3
        Apparently realising that you're not going to speak, $!{cg} breaks the silence.

"Hypothesis has given me a field assignment," she tells you, voice emotionless. "We won't be able to check in each morning."

*set covendisplay true
*label usual
Huh. The Coven's usual procedure is to pair an operative in the field with a handler back at base. You've also never known Hypothesis to give more than three assignments at once. Counting Catalyst—the only exception to the handler rule—$!{cg} is number four.

Strange that he'd pull her from supervising you when he has others on standby. The task must be important enough that he doesn't trust anyone lower on the totem pole to handle it.

*choice
    #Less supervision? That's @{coven_history concerning.|challenging.|interesting.}
        @{coven_history What happens if you unknowingly divert course? You could get punished for transgressions you didn't even know you were making.|If you thought you were in at the deep end before…|Might give you more scope to do your own thing. If you ever build up the nerve.}
        
        @{coven_history Even more to worry over. Just what you needed.|Hopefully you're prepared enough to pull this off without oversight.|Though you'd need to figure out what options you realistically have first.}
        
    #Something's up. I'll try probing her for details.
        "That's not how we usually do things," you venture.
        
        @{cg_dislike "Obviously," $!{cg} snaps, and then sighs, rubbing her forehead. "Sorry. Not your fault."|"Nope. No it is not." $!{cg} rubs her forehead.}
        
        @{cg_dislike An apology? Collector's item.|You tilt your head, waiting to see if she'll continue.}
        
        "Hypothesis gives the instructions and we follow them. All there is to it."
        
        You nod. Agreement is the only possible response.
        
    #Asking about her assignment may hold some insight.
        "What does he have you doing?" you ask.
        
        @{cg_dislike "Need to know basis," $!{cg} responds coolly. "Just know that|"I can't say," $!{cg} admits. "But} mission control has to take a back seat."
        
        Well, it's not much. Maybe you can build a fuller picture in time.

"I'll let you know when I come up with an alternative means of touching base," $!{cg} says. "We may have to fall back on rendezvous."

*if expressive > 55
    You fire her a thumbs up.

*elseif expressive < 45
    You nod.
    
*else
    "Got it."

*set vials +1
"Next, here's your Juice." She produces a familiar purple vial and presses it into your hand. "Be smart with it," she tells you as you stow the vial in your satchel. "I don't know when you'll get more."

That's an unpleasant proposition.

$!{cg} continues. "Also, I need your cover and mask names. You've picked those, right?"

"Sure," you say. @{pseudonym |It's not actually a cover, but she doesn't need to know that.} "$!{aka2}, and $!{mask}."
*page_break
*if (diming)
    *set rel_cg +5
    @{cg_dislike Much to your surprise, |}$!{cg} immediately breaks out laughing. "Are you serious?"
    
    "Yeah, for real," you reply@{cg_dislike  cautiously.|.}
    
    She smothers her chuckles with the back of her arm, but continues grinning. "$!{mask}, got it."
    
*else
    "$!{mask}. Understood."
    
That'll be passed around the place soon enough. @{diming It's unlikely anyone else will react nearly as well.|}

"And hey, Dime…" @{cg_dislike There's an uncommon softness to her expression. "Don't do anything dumb, alright?"|Her expression has softened all of a sudden. "Look after yourself, alright?"}

That almost sounded like real concern.
*if (cg_dislike)
    *choice
        #"I'll do my best." An olive branch?
            *set rel_cg + 3
            She nods, slow and thoughtful. "You always worked hard in training."
            
            Not as if there was any other choice. 
            
            You keep that thought to yourself.
            
        #"Yeah, yeah, I won't." Play it off.
            "You're filling me with confidence."
            
            "Hey, I'm your student, aren't I?"
            
            "Can't teach brains," $!{cg} counters.
            
            Ouch.
            
        #"I'm not stupid, $!{cg}." Whatever.
            *goto cggrah
*else
    *choice
        #"Learned from the best, didn't I?"
            *set rel_cg +3
            "I'm a long way from the best," she replies, a subtle smile curving her lips.
            
            "That's still pretty good."
            
            "Pff. Alright."
            
            You shrug. You're not complimenting her just for the sake of it.
        #"Don't worry about me."
            *set rel_cg +2
            "I'm your seasoned mentor. It's in the job description."
            
            *if expressive > 60
                "Seasoned?" It slips out before you can stop yourself.

            *elseif expressive < 40
                You arch an eyebrow. It's not like she's a wizened old master.
                
            *else
                "Oh yeah?"
                
            "More than you."
            
            Well. Can't argue with that.
            
        #"Don't pretend you care."
            *label cggrah
            *set cgannoy true
            *set rel_cg -5
            The softness vanishes. "Okay, be an ass then."
            
            @{coven_history You anticipate a further, harsher response, but none seems forthcoming. You relax by the tiniest sliver, berating yourself for backchatting. You should know better.|You took yourself by surprise a little there. Usually, you'd never dream of backchatting.|While it's a little satisfying to take the wind out of her sails, you probably shouldn't push it.} 
            
@{cgannoy She shakes her head, brow furrowed. "I doubt you give a damn,|There's a faraway look in $!{cg}'s eyes as she continues. "Take this how ever you want,}  Dime, but I guess I feel responsible for you. I taught you, so if something happens, it's on me."

*if (cgannoy)
    You weren't expecting her to persist with the point after you shut her down. This must be important to her.
*else
    @{cg_dislike …Hell's gotten into her? You never liked training with $!{cg} and so far as you knew the feeling was mutual. This is out of left field.|You don't know what's gotten into her. You never got the impression that your sessions with $!{cg} meant anything special to her.}
    
Can you call $!{cg} a good mentor? It's thanks to her that you have the skills you need, both socially and in combat. But they aren't the skills [i]you[/i] need, are they?

It's all for the mission. All for the Coven.
*choice
    #Still, I want to ask after this strange mood of hers. 
        "Why are you so concerned all of a sudden?" you ask, affecting a neutral tone. "You didn't get like this when I left to start the mission."
        
        "Yeah, because we would be in constant communication," $!{cg} replies. "As it stands, it could be days before I catch on to you being in trouble, and what good would that be?"
        
        You shoot her a look, narrowing your eyes. "…I'm pretty sure you told me that if I screwed up, I was on my own, $!{cg}."
        
        *goto duck
    #I'll take a light jab at her sentimentality.
        *set expressive %+ 5
        *if expressive > 60
            "Not already going all empty nest are you? It's been like a week."
            
        *else
            "I can't believe you're getting nostalgic after eight days."
            
        *if (cgannoy) or (cg_dislike)
            *set cgannoy false
            She snorts in vague amusement. "Be a smartass if you want, Dime, doesn't change what I said or why I said it." A beat. "Even if you can be kind of a tool."
            
        *else
            She snorts in vague amusement. "Be a smartass if you want, Dime, doesn't change what I said or why I said it."
            
        "Why [i]did[/i] you say it?"
        
        *goto duck
    *selectable_if (cg_dislike) #She can feel as responsible as she wants, I still don't like her.
        *set rel_cg -3
        "Okay, sure. If you say so," you say blandly.
        
        $!{cg} sighs. "I can tell I'm not getting through to you. Whatever. Hit the road, I'll be in touch."
        
        *goto theroad
    *selectable_if (cgannoy) #Maybe she wasn't through with the conversation. But I am.
        *set rel_cg -5
        "You're right," you say, leaving it just long enough for her to think you're done, and then cutting her off. "I don't give a damn."
        
        Her eyes narrow. @{coven_history Oh shit. You should have quit while you were ahead.|You keep catching yourself off guard. Maybe this is one time too many.|And there you go, pushing it.} You teeter on the brink for a moment, and then she merely throws up her hands in frustration. A reprieve. "Whatever, Dime. Trying to have a real conversation here. Fuck off back to your mission, then."
        
        *goto theroad

*label theroad
Glad to finally be through with her, you slip from the kitchenette and make for the elevator. You don't know nor care to know what any of that was about. @{coven_history There's someone much higher up the food chain you need to keep satisfied.|There's a job to do and you want to get back to it.|Another minute in this place and you're going to suffocate.}
*goto depart
*label duck
She falters. "I… never you mind that." She's suddenly very interested in the design of the kitchen cupboards. "I've kept you long enough. You should hit the road."

So, are you going to let her get away with such a blatant dodge?

*choice
    #Hell no!
        *set expressive %+ 10
        "Whoa, whoa. Hold on!" you protest. "You can't just not answer me!"
        
        $!{cg} pauses, looks you dead in the eye, and then smirks devilishly. "Whoops look at the time, I better get prepped. Later, Dime!" Without another word, she bails.
        
    #I mean. I guess?
        *set expressive %- 10
        It's so audacious that you're still stuck trying to formulate a response when $!{cg} flashes you a quick smile and coolly withdraws.
    
You're left standing there alone, staring at $!{cg}'s swiftly-retreating back. That's—she really just did you like that. You don't know whether to be impressed or infuriated.
*fake_choice
    #Impressed.
        You don't know that you've ever seen somebody just force quit an awkward conversation before.
        
    #Infuriated.
        Now you want your answer even more! Cowardice!
        
    #A weird combination of both?
        On the one hand, that was ridiculous. On the other, you kind of have to admire the guts.
        
In any case, there she goes, and now you won't know when you'll see or speak to her next.
*choice
    #Just as well, if she's going to be evasive.
        You started out having a normal briefing slash update and then everything went so far off the rails you wound up in a different country.
        
        @{cg_dislike $!{cg}'s never been this specific shade of annoying before, so you suppose there's a novelty factor at least. But hey, she's out of your hair for a while. That's a plus, right?|All of this is very unlike $!{cg}, and that's unsettling. Maybe it's better that you'll have a break from her.}
        *goto depart
        
    #@{cg_dislike Huh. Am I actually |I'm }going to miss our check ins@{cg_dislike ?|.}
        *if (cg_dislike)
            Okay so $!{cg} isn't your best friend. Or a friend, period. Yet the sense of structure brought by hearing her voice each morning has been oddly reassuring. Not even just structure. The feeling that someone's looking out for you. Cares about how you're doing. @{coven_history Even if it's more that she's watching you for the Coven.|Though perhaps it's more about the touchpoint with the Coven than $!{cg} specifically.|Even if it's just so the Coven's interests are monitored.}
            
        *else
            It's @{coven_history nerve-wracking|daunting|liberating} to be separate from the Coven, but having a touchpoint with $!{cg} each morning has been @{coven_history a salve to the tension.|a constant reassurance.|surprisingly pleasant. Far less like the oppressive overseer than you would have guessed. It's only now that you're realising that might have something to do with $!{cg} specifically.} 
            
        @{cg_dislike Even so, |}$!{cg}'s kept your head in the game for these past eight-ish days. You'll have to make do without her.
        *goto depart
    #I think she's genuinely concerned about me. @{cg_dislike There's a first.|I don't know how to feel.}
        *label notopen
        $!{cg} doesn't open up to you. Or so far as you know, anyone. In that regard, it's stranger that the conversation reached the point it did than that she skipped out on its conclusion. Your relationship has always centred around her drilling you mercilessly, an unforgiving and exacting instructor. @{cg_dislike There's a reason for your disdain towards her.|Hard to bond under those circumstances.} The best you can say is that she spares praise where it's due and @{cg_dislike yeah, you suppose you can begrudgingly admit that|that} she has a sense of humour.
        
        *if (interest_cg)
            Yet here she is showing genuine concern for your well-being. Implying that she wants to look out for you, and with a level of care that goes beyond just mission control.
            
            That makes you feel a certain kind of way.
            
            *if (brokenheart < 5)
                A way you're going to box up right the hell now, lest it begins to tread on wounded ground. She's [i]part[/i] of the wound, for fuck's sake.
                
                Your stomach twists sickeningly, bubbling a potent mixture of shame and disgust.
                *goto depart
                
            *elseif (cg_dislike)
                And it is absolutely humiliating. Getting flustered over [i]$!{cg}[/i]? Seriously, $!{mc_name}? What the fuck.
                
                Those emotions are going into the box of shame right the hell now.
                *goto depart
                
            *else
                A way you're going to… not think about for a bit. Yeah, these feelings can sit in their box for now. Maybe indefinitely, you haven't decided.
                *goto depart
        *else
            Worry is… new. You're going with new. @{cg_dislike Along with inexplicable.|} Surprising to discover there's a heart in there somewhere after the countless hours of her sending you crashing to the training mats while @{fighting_style shouting at you to keep your guard up.|demanding that you think faster, fight smarter.|pushing you to get [i]more[/i] from your powers.|DUMMY}
            *goto depart
    *if (aro !=4) #For some reason, her protectiveness brings a heat to my cheeks. @{ftone [Flirt, passive]|}
        *set interest_cg true
        *set flirt_cg 1
        *if cg_dislike
            *set t_cg true
        *goto notopen

*label depart
*page_break Time to go.
"Hold it, little ${mc_sibling}."

Catalyst's voice dashes your hopes of a smooth exit. Seconds later, he's in front of you and well inside your personal space.

*if mc_height > 4
    He has to crane his neck to look up at you. With anyone else this might have been comical. Not with Catalyst. The size difference doesn't matter in the slightest.

*elseif mc_height < 4
    You have to tip your head to look up at him. That he's taller than you is just the icing on a real terrible cake.
    
*else
    You're pretty much nose to nose with him, and you almost take an involuntarily step back.
    
Suddenly his hand snaps out, seizing your jaw in a painfully tight grip, fingers digging into your face. He forces your head around until you're meeting the dark pits of his eyes. @{coven_history "Behave while you're gone, Paradigm."|"Remember, Paradigm, you keep doing what you're told and one day you might be worth shit around here."|"Better not get any cute ideas while you're gone, Paradigm."}  He pauses, grin twitching. @{coven_history "Guess it'd be fun to remind you what happens otherwise. Just not for you."|"Don't worry. You can always count on me to keep your ego in check."|"Or do. Might be fun. For me."}

*fake_choice
    #"Thanks... for the... warning."
        *set rel_catalyst +1
        Catalyst actually laughs. "Anytime."
        
        He raps his fingers on your cheek, and then releases you with a shove to your head.
    #"Let... go of... me."
        Something feral slips into his smile. His fingers squeeze harder, and then harder still, until you could swear your bones are creaking.
        
        @{coven_history "You really do need a reminder."|"Looks like you already need a check."|"Think I heard a cute idea there."}
        
        Five seconds. Ten. Twenty.
        
        At last he shoves your head backward, sending you stumbling. Your jaw aches.
    #Stare him down.
        *if guts > 40
            *set rel_catalyst -1
            *set doubt_hypothesis +5
            You match his stare with your own, shutting out your fear. He tilts his head, brow furrowing, and his fingers begin to squeeze harder.
            
            Still, you meet his gaze. Even as the pressure on your jaw mounts, even as his smile becomes a snarl. @{coven_history You don't know why you're doing this, just that you won't stop now.|You couldn't say where this sudden bout of defiance comes from, but you aren't letting go.|Sometimes, lowering your head is too much. Sometimes you have to resist a little, if only to remind yourself you know how.}
            
            At last he shoves your head backward, sending you stumbling.
            
            As you regain your footing, you look back over and see there's something else in his eyes. Curiosity. Calculation. Both bad.
        *else
            Your nerve doesn't hold for long. Not with that grip on you. Not with two fonts of malicious glee staring back at you.
            
            With a derisive bark of a laugh, he raps his fingers on your cheek, and then shoves your head backwards.
    #Go limp.
        Best just to get it over with. No reaction means no sport. He'll get bored soon. He usually does.
        
        Not always.
        
        As you try to block those times out of your memory, Catalyst grunts and shoves your head backward, sending you stumbling.  

*label seeya
"See you around, little ${mc_sibling}," he purrs, then strides past without a backward glance.

You stop to catch your breath, massaging your jaw. Phantom fingers clutch at your face. @{touchingokay As if beating the tar out of you earlier wasn't enough, he just had to come back for seconds.|Your skin crawls, the discomfort of touch amplified threefold for it being Catalyst's hand on you.}
*choice
    #Thinking about Catalyst is a waste of energy.
        You have an entire identity to keep intact, a supervillainous team to support, and secrets to learn. In short, many more important things to worry about than a jumped up bully. Refusing to let him occupy any room in your head is a much more practical and much less dangerous form of revenge than any fanciful daydreams of taking him down.
        
        If only it were so easy to evict him from your memories.
        *goto elevator
    #I can't wait to get away from him—here.
        While you doubt you could ever forget the feeling of being watched at every moment, you'd reached the very start of relaxing some of those nervous flight or fight instincts.
        
        To restart that process will likely take twice as long now.
        
        Doesn't matter. You just want out of the building. The walls are closing in.
        *goto elevator
    #What goes around comes around. I'll get him back somehow.
        *set cattitude 2
        *if defiance < 3
            *set defiance +1
        *label payback
            
        @{coven_history You shouldn't plot revenge. Shouldn't plot [i]anything[/i]. Catalyst is just a special case. There's a sickly kind of dread in your hatred for him that makes the thought of payback all the more compelling. After all he's done—and that's where your scheming stops, a shudder snuffing out the faint coal glowing in the ashes of your resistance. All he's done, and could do again. Will [i]gleefully[/i] do again. |You shouldn't be having these thoughts. It's disloyal. It's against the Coven's interests. Just, when Catalyst heaps indignity upon punishment upon beating onto your shoulders, it gets harder and harder to keep up that team player mindset. Catalyst doesn't give a damn about cooperating with you or putting the Coven first. He hurts you because he feels like it. Because he can.|}
        
        *if ((instinctive > 60) and (coven_history = 3))
            It's been so damn hard to hold back from doing something reckless. To force yourself to wait for the right moment. A years-long war fought daily to keep your instinctive reactions in check, lest you betray your private rebellion.
            
        *elseif coven_history = 3
            How long can one person bide their time? It's been years.
            
        @{coven_history ||Years of Catalyst's abuses. Hell, today was mild by his standards. And maybe you're at your limit. }
        
        *if cattitude = 3
            *if coven_history = 1
                The shaking hasn't stopped, your shoulders heaving, your fists clenched. Today's abuses are a comradely punch to the arm compared to his past violence. And as it all rushes back through your mind, you realise that the coal isn't gone. If anything it begins to burn hotter. He'd rip you apart one piece at a time if he knew you were having these thoughts. Break you down from scratch, grinning all the while.
            
                Unless you got to him first.
            
                A manic, irrational thought. A fantasy you've visited in the past, before they ground you to dust. But maybe you've finally taken as much as you can endure. Maybe those fires aren't as dead as anyone believed. Even you.
                
                Still trembling, you carefully shield the rebellious, impossibly dangerous thoughts of vengeance, nursing that coal in a corner of your mind. And though you should, you do not bury them.
                *goto elevator
                
            *elseif coven_history = 2
                One rule for him, another for you. That's always been the way. And maybe you're tired of it. Maybe he's tested your deference for long enough.
                
                Maybe he's forgetting that even the best-trained dog will snap if sufficiently provoked.
                
                There's an ember burning in your heart that you didn't even realise existed. A flame of resistance, kindled by Catalyst today. Perhaps doomed to gutter and die, or even be snuffed out once you come to your senses.
                
                But perhaps not.
                *goto elevator
                
            *else
                If you never show any resistance, then can you even call yourself a rebel? You're little more than a good, obedient subject, dutifully following orders while fantasising about broken shackles and sticking it to the Coven. Thought without action is just make-believe.
                
                For a long time, you've kept yourself going with the inner conviction that your spirit isn't broken, that the fires of defiance still burn bright within you.
                
                But if you can't externalise that heat soon, you're not so sure you'll be able to sustain your own belief.
                *goto elevator
            
            
        *else
            @{coven_history Compared to the sum of Catalyst's violence, today's abuses are a comradely punch to the shoulder. If he decided to break you down from scratch, nothing of you would survive the return journey.|One rule for him, another for you. Hasn't that always been the way?|Thought without action is just make-believe. The list is long enough already, and 'someday' isn't going to cut it for much longer.}
        
        @{coven_history Yet you find yourself turning these thoughts, that coal, over and over in your mind. And though you should, you do not bury them.|Well. Maybe enough is enough. Maybe you're noticing the ember burning in your heart, a flame of resistance long dormant.|For a long time, the inner conviction that your spirit isn't broken has kept you going. But keep going the way you are, and it may all come crumbling down. A rebel without resistance is no rebel at all.}
        
        @{coven_history |Maybe, you just might nurse that tiny ember to life.||}
        *goto elevator
    #I don't care what it takes. Someday, I'm going to fucking kill him.
        *set cattitude 3
        *if defiance < 3
            *set defiance +2
        *goto payback
            
*label elevator
*page_break Step into the elevator.

You press your head against the wall as you descend, the coolness of the metal soothing the ache ever so slightly. Much of your body is beginning to throb, or perhaps only now is the tension receding enough for you to notice. It'll be a couple of hours before the pain truly sets in. Even fully Juiced, you're in for an uncomfortable night. You can only hope that your injuries don't hamper you from getting the ball rolling with Architect and co. To understate matters, a surprise meeting with your @{coven_history boss|benefactor|'boss'} really wasn't an ideal capper to your afternoon.

*if knowledge > 30
    *set covenbud2 true
    *set coveninfo +1
    Wait a second. You were too caught up in the moment to think about this earlier, but how the hell did Catalyst find you in the first place?
    
    You straighten up, staring at the wall of the elevator.
    
    He was on you within a half dozen blocks of the apartment building. That's way too fast to be a coincidence. He knew exactly where you were, and yet you're certain that he wasn't tailing you. Hypothesis would consider it inefficient, and Catalyst isn't patient enough to wait around outside.
    
    Which can only mean that you're somehow being tracked. An implant? No, Hypothesis is far too controlling to put tech inside any of his subjects, and given your biology, the chances of you either detecting or inadvertently ejecting such a device would be too high. Leaving…
    
    Your earbud. It has to be the earbud. $!{cg} made very clear in her briefing that your earbud must stay with you at all times. Sure, it keeps you in contact, but a small and unobtrusive piece of gear? Sounds like the perfect place to install a tracer.
    
    The elevator comes to a stop. You carefully file the deduction away for later. Could come in handy.
    
*else
    Closing your eyes, you try to will away the pounding in your skull, remaining in place until the elevator comes to a halt.
    
*page_break Leave. Leave.   
    
"Until next time," Lullaby says as you rush past them and burst back outside.

Crossing the street and rounding the next corner, you immediately collapse against the nearest wall, heaving great gulps of air. Finally you can breathe again. 

Your composure is slow in returning. Truthfully, your guard was down after meeting the rest of the crew and the last thing you expected was a a summons sealed with a fist. A painful advisory that the Coven's arm is long and its claws are sharp. Hypothesis may have finally allowed you into the field, but you're still beholden to his every command. At best you have the illusion of freedom.
*choice
    #So I should concentrate on my orders.
        *set defiance -1
        Orders are the constant, whether inside HQ or out doing Hypothesis's bidding. As such, keeping them at the forefront should prevent a siren song from tempting you with notions of escape.
        
        *if cattitude > 1
            @{coven_history Maybe you're just fooling yourself, holding on to that little coal.|Maybe that ember isn't burning as brightly as you thought.|And you're already back to biding. Why even bother?}
            
        *else
            That's the best way to stay safe. Stay alive.
            
    #Better than nothing at all.
        Your standards are incredibly lofty, it's true.
        
        Still, less than two weeks ago, you hadn't been outside in over five years. Beggars can't be choosers.
        
    #If only I could leave for real.
        *set defiance +1
        You're filled with sudden longing.
        
        Walk away. Keep walking until there's no more Alderbrook. Go to the heroes. Knock over a couple of stores and then skip town.
        
        If only.
        
    
Within your satchel, the vial sits heavy as an anchor, dragging you inexorably down to your fate.

It always comes back to Juice.

[i]As with previous iterations, subject quickly deteriorates when deprived of the formula. The biological alterations induced by the formula demonstrate the standard effect of beginning to consume the host's biomass as a fuel source. Given the ample records of this effect and the novel nature of the subject's changes, the formula will be reintroduced to their system—[/i]

That voice—Hypothesis's voice. Calmly narrating notes and observations, as if your powers weren't slowly devouring you from the inside out, as if you weren't writhing and screaming while every fibre of your body burned in agony. That voice. Deciding to spare you simply because he'd [i]seen it before.[/i]

You can hear him clear as day. A tether back there and back [i]then[/i]. A reminder and an ultimatum.

The Coven—Hypothesis—has no need of restraints. No fear that you'll slip the noose. Go rogue, stop dosing, and your own powers will eat you alive, piece by piece.
*choice
    #But there's nothing I can do.
        *set content +1
        You're stuck like this. You can't begin to speculate how the process could be reversed, and it's not like you've got a lab and a dozen assistants lined up to research how.
        
        These powers are a part of you, like it or not.
        
    #Powers? Parasite, more like.
        *set hate +1
        You've never heard of a parahuman whose abilities will just straight up kill them. So what else can you call this thing inside you, leeching your life away? @{speciality The nodes make it pretty fucking obvious what's up.|||DUMMY}
        
        These aren't parahuman powers, they're an infection without a cure.
        
    #Couldn't I have just ignited?
        *set trade +1
        Flares aren't well understood. Nobody really knows what causes people to suddenly develop powers, other than danger and/or trauma coming hand in hand with ignition.
        
        If ever there was an opportunity, it was that night. And nothing.
        
        It just—weren't you feeling the same pain and panic as Beth and Prii? Why them, and not you?
        
        Why weren't you good enough?
       

The Juice, Hypothesis's formula, it tears up every book there is on power theory. Genomes develop their abilities naturally. Flares gain them in their hour of need. Augments are souped up on cybernetics, and even then, there's some kind of interaction with the other subtypes; every attempted augmentation of a genome or flare has failed horribly. The three methods. Everybody knows them.

Then there's the Coven. All of you Juiced—you've seen everyone dosing at one point or another—save the two mercenaries and Hypothesis himself. All of you with different abilities. Quietly flying in the face of what everyone thinks they know about powers, dancing to the tune of one man.

A man very interested in Alderbrook's Zone.

As always, an encounter with Hypothesis leaves you with more doubts than ever before.

*page_break Head home.
*achieve coven
*set met_alistair true
You don't have the energy or the brain space for anything else.

Trudging back through the streets takes twice as long as it should, your pace slowed by fatigue both physical and mental. By the time you reach Wesson Parks, the sun is beginning to set. The mechanical carcasses of your industrial building cast long and misshapen shadows as you cross its span, home amidst the monsters.

Stepping around another rusting hulk, your shipping container comes into view. And so does something—some[i]one[/i]—else.

A man stoops in front of your home. There's a plastic dish in his hands.

It's @{alidisplay the pasta ninja!|Pasta La Vista!|}

He sees you a split second after you see him, leaping to his feet—damn he's tall, and muscular too—and smiles. "Hey there! Uh, promise this isn't as weird as it looks?"

He has dark skin, glasses, and a clean shave, with his hair drawn back in a neat tail of braids. He's dressed casually, cargo pants and a white shirt with a red jacket thrown over the top, though he's also wearing a backpack. Definitely a lot more put together than the average Wesson Parks resident.
*choice
    #"Who the hell are you?" I bristle.
        *set expressive %+ 7
        *set bristle true
        *goto leavebad
    #"I dunno, dude. It looks pretty weird."
        He glances from you to the dish he's holding, and his smile turns sheepish. "Yeah, naw, you've got a point."
        
        *if expressive < 40
            You fold your arms and raise an eyebrow, inviting him to elaborate.
            
        *elseif expressive > 60
            "I usually do," you reply, a smile of your own trickling onto your face. "Want to take a shot at making it less weird?"
            
        *else
            "Feel like explaining what you're up to?" you ask.
            
        *goto alisplain
    #"...Hi."
        *set expressive %- 7
        Despite your minimal response, his smile broadens.
    #Silently begin hunting for signs of an ambush.
        *set instinctive %- 7
        There are too many tight angles and blind corners here. It's impossible to tell whether anyone is lying in wait.
        
        You unconsciously begin backing up in an attempt to improve your line of sight.
        
        "Whoa whoa!" Panic flashes across your visitor's face. "Hold up! You don't gotta worry, I'm just a guy."
        
        *if observation < 20
            You hesitate. He seems sincere, but you're also terrible at reading people.
            
        *else
            You hesitate. He does seem sincere, but maybe he's a good actor.
            
        "Talk," you say after a little deliberation, though you're still keeping your head on a swivel.
        
        *goto alisplain
    #"Leave, or I'll make you." This is bad. He needs to be gone.
        *set instinctive %+ 7
        *label leavebad
        *set hostile true
        "Whoa whoa!" He holds out both hands. "Hold up a sec. I'm not a cop or a suit or nothing. Just a guy."
        
        @{bristle You almost snort with derision. Sure. Just a guy.|Your fists begin to clench. Sounds like excuses.}
        
        "Can I get a chance to explain?"
        
        You exhale hard from your nose. "Make it fast."

*label alisplain
"Aight. So. I volunteer with a non-profit that looks out for folks sleeping rough, and I swing by the Parks when I can. Last time I was here, I got a hunch someone was living in the building. Figured I could help out by dropping off some food." He's smiling @{hostile again|still}, but @{hostile this time it's|it has turned} intensely awkward. @{pasta However, he then brightens up, raising the dish. "And hey, saw you picked up the thing I left this morning. That, uh, was you, right?"|Almost pained, in fact. "I uh, see you weren't into the thing I left this morning."}
 
Your stomach interjects with a loud rumble, reminding you that @{pasta a couple forkfuls of the very same are all you've eaten today.|you haven't eaten a thing all day.} You focus on the man, trying to ignore your hunger.
 
Politely, he does not comment. However, his eyes do widen. "Dammit, forgot! Name's Alistair. Hey. Again."
 
He trails off. Your turn.
*choice
    #"You drop food in abandoned buildings often?" I'm teasing.
        *set rel_alistair +10
        
        *if expressive < 35
            Or [i]trying[/i] to tease at least. Your question comes out so deadpan that he's clearly unsure how to take it. After a moment, he seems to decide you were asking him for real. "It's not like that."
            
            *goto dropfood           
        *else
            @{hostile He takes a second to reply, probably due to the switch up from your hostility a moment ago.|He straightens an imaginary tie.} "Oh yeah, guerilla pasta is the next big thing. Heard it here first." He laughs. "But uh, for real, this is extra. Normally it's the soup kitchen."
            *goto soup
    #"You drop food in abandoned buildings often?" I'm legitimately curious.
        *set rel_alistair +10
        
        He laughs self-consciously. "It's not like that."
        
        *label dropfood
        "Then how is it like?"
        
        "Normally we do outreach. We've got a soup kitchen and a shelter. This is extra." He grins. "Guerilla pasta isn't the usual."
        *label soup
        
        You have a regular good samaritan on your hands. Or somebody who claims to be. 
        
        That's a souring thought. In truth Alistair could be anyone, and his presence is inherently dangerous.
    #"I don't need help." And help is dangerous.
        "It's nothing to be ashamed of." His expression is sympathetic. "Anyone can get into a bad spot, you feel me?"
        
        A bad spot is the understatement of a lifetime. You can't help the wry smile twitching its way onto your face. If only he knew.
        
        With you silent, Alistair speaks again. "I'm not judging. Promise."
        
        Yeah, no. Judgement isn't the problem here.
    #"Well... thanks I guess?" @{pasta |Even if I passed on the food.}
        *set rel_alistair +10
        "No prob!" @{pasta | He glances away, and you realise he's looking at the pasta from earlier, still untouched atop the barrel. "And uh, no sweat that you didn't eat it. Probably kinda worrying?"}
        
        @{pasta Ah man. You could really go for some more food right now.|"Something like that."} You exchange quick smiles, his far broader than yours.
        
        The moment of connection fades swiftly, leaving a sour aftertaste in its wake. You can't shelter from reality for long, and the truth of the matter is that Alistair's presence is inherently dangerous. He could be anyone.
    #Say nothing. I want him gone, but I can't arouse suspicion.
        *temp goaway true
        Having your home compromised is bad, but overreact and there's the potential for this to snowball into an absolute disaster. Alistair would only have to blab to the right—or wrong—people about a random drifter roughing him up, and then you could be forced from your hideout.
        
        Hypothesis will not be finding you another.
        
        "…Sorry. Realising I'm kinda in your space."
        
        Great. So maybe take the hint and go?

*label idkthis
*page_break
*set alidisplay 3
This feels unnavigable. Nothing about Alistair screams trap or trick @{goaway and you're struggling to distinguish between justified paranoia and ruinously overreacting to the situation.|and even if you're justified in your paranoia that doesn't make the pill any easier to swallow.}

A short stint in the Coven and you're straight back to jumping at shadows.

"Look, I dunno your situation and I'm not gonna ask, but if you need anything, I left our card on here." He raises the new dish. "No strings. Just a helping hand."

You look into Alistair's face and see only well-meaning concern. In some ways, that's the killer. It almost doesn't matter if he's exactly as charitable as he claims, he's a threat just by knowing where you live. He could screw you over with ease, and it wouldn't even need to be intentional.
*choice
    #Despite that, I can't bring myself to turn him down.
        You know full well it's extremely dangerous to keep him here any longer than necessary.
        
        @{goaway Heck, you were just stopping yourself from telling him to go away. And now you find that you can't.|}
        *choice
            #@{goaway |Even so, }I just don't have the heart.
                Call it sentimentality. Call it desperation for a human connection. Whatever the reasons, you're finding yourself reluctant to say anything that might blunt that earnest expression.
                
            #I'd rather have him on my side than not.
                *set instinctive %- 7
                The cat's already out of the bag. Trying to keep Alistair sweet makes the most sense.

            #I am a bad ideas factory.
                *set instinctive %+ 7
                Correct!
                
                If nothing else, you're honest in your self assessments.

        He's waiting patiently for a response.
        *choice
             #"Thanks."
                 *set rel_alistair +10
                "Sure thing." He looks incredibly pleased.
                *label onsleeve
        
                If this guy's heart was any more on his sleeve, his jacket would be monogrammed with them.
                
                It feels odd to be around. Everyone you know is either Coven or part of your assignment. An expressive person with no apparent ulterior motives out in the wild is…
                
                You can't put words to the strangeness that you're feeling. There's a hollow in your chest, and you don't know what's supposed to fill it.
                *goto alistay
            #"Thanks." I'm not sincere.
                *if subterfuge < 20
                    "Sure thing." He looks disappointed. You suspect you didn't hide your lack of interest particularly well.
            
                *else
                    *set rel_alistair +10
                    "Sure thing." He looks so pleased that you almost feel a little guilty for not meaning it.
                    
                *goto onsleeve
            #"I'll think about it." I have no intention of thinking about it.
                He fixes you with a rueful grin. "Heard that one before, but it's all good." Even still, disappointment is writ large on his face.
                
                *goto onsleeve

    #The sooner he's gone, the better.
        Letting him stick around is dangerous. The only choice is how direct to be.
        *choice
            #"Thanks for this, but I'd like to be left alone now."
                *set aliscram true
                Alistair's face falls, but he quickly recovers, nodding understandingly. "I hear you. I'll head out."
                *goto aliout
            #"Cool. Get lost."
                *set aliscram true
                @{hostile He closes his eyes for a moment, a look of acceptance on his face.|Your bluntness seems to catch him off guard. Still, he gives you a slow nod.} "Aight, I hear you. I'll dip."
                
                *label aliout
                You watch Alistair carefully as he swings his backpack to the ground, but it's only to peel something from the front of the dish before stowing the pasta inside the bag. Standing back up he @{pasta | goes and collects the previously-rejected container too, then} takes a couple of steps in your direction. You shift your weight and continue eyeing him.
        
                "Listen, you ever change your mind, all you gotta do is call." He raises what he took from the dish, a small card, and then holds it out to you. When you make no move to accept it, he simply stoops and places it on the ground. "See ya. Take care."
                
                Alistair powerwalks away. You move to the closest piece of machinery, peering around its side to keep him in view for longer. His course remains unerring, and he swiftly disappears from sight.
                
                You clench your jaw tight, and then turn back to your container. Enough. This has been a hell of a day and you're ready to end it.
                
                *page_break Collapse into bed.
                *goto fitful
   
        

*label alistay
"Hey, so, I've kinda been calling you 'containerguy' in my head for a couple days now—uh. Guy as in, gender neutral guy, I dunno whether—" Alistair stops, letting out an embarrassed laugh. "Anyway, can I get your name? 

*choice
    #Screw it. I've already come this far.
        *set aliname true
        *set rel_alistair +5
        No point being coy when you're letting him stay.
        
        *if ((nickname) and (not (pseudonym)))
            "$!{forename}. But you can call me $!{aka}. $!{mc_he}/${mc_him}."
            
        *elseif (pseudonym)
            "I'm $!{aka}. $!{mc_he}/${mc_him}."
            
        *else
            "I'm $!{aka}. $!{mc_he}/${mc_him}."
            
        @{pseudonym There's absolutely no way you're inventing a fresh cover identity on the fly. Best to keep it simple. |And now that's another person you've told your real name. There's something freeing about it.}
        
        *if (not (pseudonym))
            *set doubt_alistair + 20
            Alistair's smile falters, then turns strange. "Sorry, uh, say that again?" He looks perplexed.
            
            "$!{aka2}," you say uneasily.
            
            "Huh." He shakes his head abruptly. "Sorry!" he repeats. "Just thought of something weird."
            
            Well, that isn't concerning at all.
            
            *goto alicont
            
        *else
            "Thanks, container$!{aka}." His grin is infectious, though you soon recover.
            
            *goto alicont
    #Hahaha. No.
        There's no combo bonus for bad decisions.
        
        *set doubt_alistair +5
        *if expressive > 65
            "Nope."
            
        *elseif expressive < 35
            You shake your head.
            
        *else
            "No, sorry."
            
        Alistair huffs an incredulous laugh. "Guess I can't make you. Aight. No sweat."
        *goto alicont
    
*label alicont
"So, charity work, huh?" you say, mostly to deflect.

Alistair nods eagerly. "You got it! Been volunteering most of my life. Just find it real rewarding to help folks out, you know?" He pulls a face. "Lot more satisfying than the day job."
*choice
    #Nobody's this nice.
        Prii was. Shauna was.
        
        The thought crashes into you like a hammer. You struggle to swallow the lump in your throat.
        
        Dammit. Dammit. Dammit.
        
        You have to turn your face away from Alistair to hide the sudden wetness of your eyes. @{(expressive < 30) Fortunately, you're stoic enough to freeze the imminent tears into your heart, avoiding any telltale signs of your emotions.|You swipe at them furiously. You're not doing this in front of a stranger.}
            
        Alistair is studying you all too closely as you look back in his direction. "@{aliname $!{aka}? |}You okay?"
        
        "Fine," you mutter.
        *choice
            #Shut right up.
                There's no answer that would come remotely close to explaining. Even if you had one ready, you sure as hell couldn't risk telling this guy.
                
                "Aight then," Alistair says, and then trails off.
                
                *goto gottarun
            #Give a vague explanation.
                *set doubt_alistair +5
                *set rel_alistair +10
                "Just… difficult memories. That's all."
                
                Difficult. That's one way to describe them.
                
                "Oh. Gotcha. My bad."
                
                It's nothing close to his bad, yet he still looks incredibly doleful about it.
                
                *goto gottarun
    #I need to keep him at arm's length as best I can.
        So long as the conversation stays superficial, you're relatively in the clear.
        
        Relative to what's a capital S Situation, but this is about as good as it gets when you decide to ignore common sense.
        
        "You local?" Alistair asks.
        
        Well never fucking mind.
        *choice
            #Tell the truth. Sort of.
                "No," you reply. "But I've been in town a while."
                
                You omit the part where most of that time was spent locked up inside HQ.
                
                *goto gottarun
            #Deflect again.
                "Been around the block," you say, half shrugging. "You?"
                
                "Born and raised!" Alistair replies happily, deflected.
                
                *goto gottarun
    #In spite of myself, I'm getting drawn in. Keep the conversation going.
        *set rel_alistair +10
        Getting to chat a little is nice. Which goes to show how socially starved you are.
        
        Well, whatever. May as well make the most of the talk while it lasts. "What do you do then?"
        
        "Oh, uh." He looks away, and then back. "It's boring. You don't wanna hear about that."
        
        Ways to ensure $!{mc_name} definitely does want to hear about it, exhibit A. "Aw, come on. You can't drop a mention then just stop."
        
        Alistair drops his eyes with an embarrassed smile. "Freelance IT." He fiddles with his glasses. "Happy?"
        
        *if knowledge > 50
            "Hey, I can respect someone who knows his way around computers. I'm pretty handy with them myself."
            
            *label pointers
            "Yeah?" His self-conscious expression ebbs. "Nice. Tech geeks represent."
            
            You nod in shared friend-who-fixes-the-internet solidarity.
            
        *elseif knowledge > 33
            "Sure I am. I'm decent with computers, but I bet you could show me a few pointers."
            
            *goto pointers
        *elseif knowledge < 20
            "Computers are sorcery so far as I'm concerned. You're a brave man."
            
            He laughs. "They're not that scary. I bet you'd pick it up no trouble in the right environment."
            
            *if expressive > 55
                "Whatever you say. Sorcerer."
                
            *else
                "If you say so," you reply dubiously.
                
        *else
            "IT? I can see it."
            
            "Dunno whether that's a compliment," Alistair laughs.
            
            *if expressive > 55
                You shrug mischievously. "Maybe. Maybe not."
                
            *else
                You shrug. "Take it any way you want."
                
        "Speaking of. I uh, I dunno what your work situation is like, but we've got a program to help folks. If, you know, if you wanted."
        
        You're back to reality with a splash of ice water. What the hell are you doing? He's making a natural continuation of the conversation, and that's exactly the problem. The more normal this little chat gets, the closer you'll come to exposing your life as anything but. @{hostile Dammit, you had the right idea when you gave him the cold shoulder! How the fuck did you go so wrong, so fast?|}
        *choice
            #I miss this so badly.
                It's dangerously intoxicating.
                
                You know you shouldn't, and you still can't stay away.
                
                "Right, okay. Thanks," you manage, which is enough to get you another smile that you shouldn't want.
                *goto gottarun
                
            #Focus. I need my head in the game.
                You're so close to the line you might well be stepping on it, but you haven't crossed over into the real shit just yet. There's a chance to salvage things and safeguard your secrets so long as you start playing this with your head instead of your heart.
                
                "Thanks," you say neutrally. 
                
                Alistair—hopefully—still isn't any the wiser.
                *goto gottarun

*label gottarun
In the ensuing silence, Alistair checks his watch then double takes, eyes widening almost comically. "Crap! Gotta go!" He fumbles around in his pockets, precariously balancing the pasta dish in his arms. You watch the container bobble, expecting it to smash onto the ground at any moment.

Surprisingly that moment doesn't arrive. Instead, Alistair triumphantly extricates a well-chewed pen from his jacket. Popping off the cap—which promptly goes flying, rolling under a piece of machinery—he scrawls something on the lid of the dish, and then presses the whole container into your hands.

"Nice meeting you! Later!" He's gone before you can say a word.

*page_break What... just happened?
You feel like you just got bowled over by a hurricane.

Okay so Alistair probably saved you from yourself by dipping, but he went 0-100 in about half a second. Now he's gone, leaving only questions and a faint aroma of tomato sauce.

You look down at the dish in your hands. A spidery string of numbers stretches across the lid alongside an unassuming business card for Alistair's charity.

Erasing them right now would be the smart choice. A dash of reason to patch the foolishness of the past few minutes.
*choice
    #But I won't.
        *set alinumber 2
        You stare at Alistair's phone number.
        
        Trust is a strange thing. It wasn't always so foreign.
        
        And trust is the only word to describe it. You're trusting that he's just an ordinary guy with nothing to hide. You're trusting that he won't say the wrong thing to the wrong person at the wrong time.
        
        There are a dozen ways Alistair can ruin you and it'd take little effort to think up a dozen more. Keeping his number is a conscious decision to disregard all of them.
        
        Lowering the dish, you head for your container. No more second guessing. Not today, at least.
        
    #I scrub the numbers out.
        *set alinumber 3
        The ink hasn't settled properly on the plastic, and rubs off with a simple wipe from your sleeve.
        
        There's a bizarre pang of regret, which you promptly suppress. You aren't starting back up with the second guessing; this is the best decision you've made since you got home.
        
        Speaking of which, it's time to head for the container.

And hey, pasta for dinner.
*page_break Eat, then pass out.
*label fitful
*set juice -10
Your slumber is fitful, haunted by snatches of Hypothesis's voice. You awaken in a cold sweat, still feeling the gaze of endless eyes.

The sun has beaten you up today. You can't see from inside the container, but its heat warms the metal. With a lurch of alarm, you reach for your earbud before remembering that there's no $!{cg} check in for you to miss. Even so there's too much on your mind for you to sit idle, and you disentangle your limbs from your @{livingconditions cruddy blanket|blanket|duvet} to haul yourself out of bed. 

After wetting your face with a handful of frigid water, you busy yourself by repeating yesterday's routines. However, practicing on your skills can only occupy you for so long, and wandering thoughts encroach on your concentration. Short on options and not wanting to be at a loose end you venture sending a message to Dion, enquiring after the plan for today. That shouldn't come across as too eager, right?

You realise that you're over-analysing the first text you've sent in half a decade. A humourless grimace of a smile curls your lips.

Within a minute, your phone beeps.

[i]Was planning on meeting in a few hours. You can stop by earlier if you want, it's no problem.[/i]

A second text follows with the full address. You're almost a little disappointed to find that Dion doesn't text with the same formal diction he talks. Though at least he doesn't use emojis and chatspeak; you think the whiplash would fully take you out. Gathering your things, you gear up and exit your home.

No pasta waiting outside this morning. Disregarding everything else about the Alistair situation for a moment, you're still uneasy that he stumbled across the shipping container with so little effort. Lest you forget, you're a wanted criminal now. Who the hell makes a habit of strolling around old abandoned buildings anywayyy—ahh goddammit.

It's a quiet, clear morning in Alderbrook. Decent conditions for the significant walk ahead of you. This new location is on the outskirts of town, far away from any of the previous meeting points, and even if you could afford to hop on a bus, Alderbrook's public transport ranges from sporadic to non-existent. 

As you put one foot in front of the other, your thoughts stray.
*temp whomst 1
*temp thanksmal false
*choice
    #To the Coven.
        And specifically…
        *choice
            #The mission.
                Discover your new team's plans. Unmask Architect and Wyrd. And as of yesterday, connect the dots on the Zone.
            
                Not asking too much of you, huh?
                *goto walkingon
            #Yesterday's briefing.
                Being recalled like that was unusual, no two ways about it. 
            
                Reactive. That's the word you're hunting for. The whole change in strategy was reactive, almost kneejerk. What is it about the Zone to provoke a response like that?
            
                You have no answers.
                *goto walkingon
            #My loyalties.
                *if (defiance > 2)
                    What loyalty has the Coven earned?
                
                    @{coven_history As recently as a fortnight ago, you would have flinched away from a thought like that, dreading the consequences of allowing it to so much as pass through your mind.|Perhaps you're not so under the boot as you thought. You've behaved. You've toed the line. And there's no reward. Nothing but endless service.|You've felt this way a long while. You've kept it inside, letting it fester, pacing like a caged lion.}
                
                    @{coven_history That you're allowing it to remain, that you're even having the thought… it's a sign. A tentative and wary sign.|Maybe you're opening your eyes at last.|Now you're out of the cage, and maybe it's time the lion was too.}
                
                    @{coven_history Of what, you can't say for sure.||}
                *else
                    @{coven_history Any step out of line will be directly into a world of pain. Catalyst yesterday was barely a sample.|It's an unpleasant truth that you owe them your life. All you can do is make the best of a bad situation.|No matter how you feel, you're shackled to the Coven. Dependent on the Juice as surely as you need food and water.}
                
                    @{coven_history Submission is survival. It's that simple.|Your life is easier with the Coven onside than when they're not. It's that simple.|Maybe loyalty isn't the right word for it, but so long as that sword of Damocles hangs overhead, you have no choice.}
                *goto walkingon    
    #To the past.
        Specifically…
        *choice
            #Before everything.
                You had a life. Friends. @{dating A partner.|} Hobbies. A job. 
                
                Okay, not a glamorous job but it counts.
                
                Now you've got @{speciality twisted little creatures living inside you|a body seething with barely-controlled power|a shell like you're some kind of bug|}, a substance dependency, and a criminal record. @{(subterfuge > 50) …a [i]worse[/i] criminal record.|}
                
                You miss it. Down to the obnoxious customers complaining their order is wrong. @{(expressive >= 65) Albeit maybe the idea of shushing a Karen with a tendril is sort of fun.|}
                *goto walkingon
            #That night...
                In your mind's idle moments, it's all too easy to drift back to when it began. To @{origin the fear that sent you bolting into the dark.|the exit closing before you and extinguishing your hopes.|stumbling in the dark, desperate and alone.|facing down the nightmare without hope of victory.|the thing's jaws slowly closing around you.|the exit closing before you and extinguishing your hopes.}
                
                *if origin = 1
                    Just thinking about it gives you an echo of that fear. @{guilt Next, the guilt. And that's certainly no echo.|Then, though you strive to justify to yourself what you did, the doubt creeps back in.| From it you try to shape the mortar of your own justifications. Surely anyone can see that running was the reasonable choice.}
                    
                    @{guilt You left them.|Coward.|Yeah…}
                    
                *else
                    @{origin |You were so close. So, so close.|In a way, you've been alone ever since.|You and Prii. Brave, brave idiots.|You can still remember the stench of its breath. Then again, that's not your only example of the sensation.|You were so close. So, so close.} 
                *goto walkingon
            #The experiments.
                Purgatory.
                
                Strapped to an operating table as blinding lights shone into your face. Hypothesis's voice with its countless reports and notations.
                
                The Juice. Your tendrils. The membrane writhing across you. Thousands of tiny teeth gnawing your—
                
                You stop, grinding the heels of your palms into your temples. Enough. Enough. Enough.
                
                It's some time before you're able to will yourself into motion again.
                *goto walkingon
    #To a person.
        Specifically…
        *choice
         #From my new team.
            *choice
             #Dion.
                Taciturn. Secretive. If he played his cards any closer to his chest they'd be under his shirt.
                
                In several ways, Dion's the centre of everything. He's why you're here. He, more than anyone, needs to be kept in the dark. You can't let him suspect anything.
                *set whomst 1
                
                *choice
                    #What does he have to hide?
                        The million dollar question. Secrets come with the territory. That's why parahumans wear masks.
                        
                        Dion, though? Cloak and dagger even by those standards.
                        
                        What will you find when you peel back the veil?
                        *goto walkingon
                    #To be honest, I'm really just hoping that he likes me.
                        *label befriends
                        You know it's kind of pathetic, but you don't think you can be blamed for being a little desperate. Who do you have? @{ari There's nobody.|Airy?|Airy? $!{cg}?}@{(ari > 1)  Yeah sure okay.|}
                        
                        Craving validation is natural when you haven't had a normal friendship in years. @{(expressive > 60) You've got to be the world's most company-starved extrovert.|Everyone needs a little company.}
                        
                        So yeah, maybe that means you're agonising over the approval of a @{whomst secretive supervillain with an unknown agenda|criminal with a self-professed habit of screwing with people|strange half-sheep girl|sullen dude with a double quota of bones|person who stepped straight out of a vampire novel} like it's a high school party. Sue you.
                        *goto walkingon
                    #I'm still thinking about how he handled the fight with the Hounds.
                        *label beallies
                        *if whomst = 1
                            Architect, along with Wyrd, had the battle decently in hand. That said, without your intervention they probably wouldn't have managed to take down Arcade and Enfilade before Surpass showed up. That's where things would have got very dicey. Would he have just cut his losses? Would Dion still have resorted to threatening a bystander? 
                            
                            And if those circumstances crop up again, will he actually carry out the threats?
                            
                        *elseif whomst = 2
                            Right. Even if they were holding their own before you showed up, Surpass completely cleaned their clock.
                            
                            Hopefully you'll be able to rely on them when push comes to shove.
                            
                        *else
                            While most of your combat experience is from instruction, it still puts you on a different level to someone who has never been in a mask fight. @{whomst DUMMY|DUMMY|Kay|Teddie|Wil} fits the bill. Unless you're making an assumption.
                            
                            Either way, there will be more battles in the future, and you need to be able to rely on @{whomst DUMMY|DUMMY|her|him|${whim}}.
                            
                        *goto walkingon
             #Mal.
                *set whomst 2
                *set thanksmal true
                They're a strange one. You don't entirely know what to make of them.
                
                Mallory almost seemed like they weren't taking the throwdown with the Glory Hounds seriously. @{(expressive >= 65) And that's coming from you.|} It's difficult to get a read on the type of person who shrugs off getting smashed across the room with a laugh and a smile. You know from experience that taking a hit like that isn't fun and games.
                
                Can't forget that they admitted to messing with you just because they could, either. Or that they started openly checking you out. @{interest_wyrd Or that you were kind of into it.|}
                *choice
                    #They don't act like someone with something to hide.
                        Heck, they wear a domino mask. You've known people to connect the dots of a parahuman's previous identity based off a lot less information than that.
                        
                        Mask fanboys get very, [i]very[/i] into their analyses.
                        
                        Point is, if Mal has a secretive bone in their body then you've yet to see it in evidence.
                        
                        That should be a relief; it makes your job a whole lot easier. Instead, their blasé attitude evokes little more than a faint feeling of unease.
                        *goto walkingon
                    #It wasn't exactly an impressive showing against the Hounds.
                        *goto beallies
                    #Despite all that, I'm mostly just hoping that they like me.
                        *goto befriends
                    *selectable_if ((aro != 4) and (not (interest_wyrd))) #The last one. That's why they're on my mind. @{ftone [Flirt, passive]|}
                        *set interest_wyrd true
                        *set flirt_wyrd +1
                        Okay yeah. You can concentrate on the odd attitude or how the battle went, but you know full well that you're just trying to deflect. Your thoughts keep drifting to Mal because of the flirting, simple as that.
                        
                        Dammit.
                        
                        It's been a long time. A long, long time. And, well. It's kind of nice. Though you're not sure what it says about their standards, considering your five-plus-years-confinement, ragged third hand clothes looking ass.
                        
                        Maybe you're a little too desperate for any kind of positive attention. @{(brokenheart < 5) Maybe you're just looking for anything that can patch up the hole in your heart.|}
                        *goto walkingon
               
                    *if (interest_wyrd) #Yes. Yes I was. Dammit. @{ftone [Flirt, passive]|}
                        Hot off the presses, the latest issue of $!{mc_name}'s Terrible Ill-Advised @{(aro > 1) Flirts|Crushes}.
                        
                        Getting involved with anyone wouldn't be smart. Just, you know, $!{mc_name#1}TI-A@{(aro > 1) F|C} wouldn't be the publication that it is if you were smart.
                        
                        Whatever. Mallory's cute. Doesn't have to mean anything or go anywhere.
                        *goto walkingon
    
             #Kay.
                *set whomst 3
                The fluffiest of your new companions. It's not often you can see someone's parahumanity at a glance, but then there Kay is with her horns and eyes and colouration.
                
                Can't be easy for her. You're able to hide your @{feature hair within your membrane, and otherwise pass it off as dye.|eyes under your membrane, and otherwise spin a story, or claim they're contacts.|veins under your clothes so long as you're careful.|marked abdomen under your clothes so long as you're careful.} Kay's stuck with what she's got.
                *choice
                    #But never mind any of that. I'm just hoping she likes me. @{interest_kay And not even in the more-than-friends sense.|}
                        *goto befriends
                    #Which better be enough to hold up in a fight.
                        *goto beallies
                    *if (interest_kay) #Still distracted by the cute girl, huh $!{mc_name}? @{ftone [Flirt, passive]|}
                        *set flirt_kay +1
                        *label distracted
                        *if flirt_kay = 2
                            Yup. Still distracted. @{(brokenheart < 5) Still guilty about it.|}
                            
                        *else
                            Preoccupied@{(brokenheart < 5)  and guilty about it.|, that's one word for it sure.}
                            
                        You're absolutely hopeless. @{(brokenheart < 5) Faithless too, apparently.|} In the middle of an undercover assignment that could literally get you killed, and you're fixating on @{(flirt_kay = 2) someone's pretty smile and sparkling eyes.|the smouldering eyes of a guy about as personable as a rock.} 
                        
                        @{(brokenheart < 5) The more you try to dislodge the thoughts, the deeper the barb seems to dig. The feeling of betrayal, like you're letting $!{prev_li} down.|Skewed priorities much?}
                        
                        Urgh.
                        *goto walkingon
                    *if ((not (interest_kay)) and (aro != 4)) #Honestly, I'm beginning to think that Kay's in my head for reasons a little more than just friendly. @{ftone [Flirt, passive]|}
                        *set flirt_kay +1
                        *set interest_kay true
                        Yup. That's about where you are right now.
                        
                        It's… it's fine. You can handle these kinds of feelings. The attraction kind of feelings. The ones that have Kay all over your mind.
                        
                        Fuck. Dammit.
                        *goto walkingon
             #Teddie.
                *set whomst 4
                The prickliest of your new companions. Literally as well as figuratively, considering all those bony spurs.
                
                *if (antagonise)
                    Heck, you kind of fought with him already huh?
                    *choice
                        #Regretting that one a little. We need to work together.
                            *label patch
                            Right. It was a bad first impression on both counts, but you're a team now. You need to be able to coexist.
                            
                            @{(whomst = 5) Wil seems personable enough, we can probably talk it out.|Talking it out might be a challenge. Teddie doesn't strike you as the forgiving type.}
                            
                            Still, you'll have an opportunity soon enough.
                            *goto walkingon
                        #It doesn't matter so long as he's reliable in a fight.
                            *goto beallies
                        *selectable_if (aro != 4) #Do not think about how that glower makes me feel. Do not. @{ftone [Flirt, passive]|}
                            *set flirt_teddie +1
                            *set interest_teddie true
                            *set t_teddie true
                            Too late.
                            
                            For [i]fuck's[/i] sake.
                            *goto walkingon
                    
                *else
                    Avoiding his bad side may be difficult.  
                    *choice
                        #His surliness kind of just makes me more anxious for him to like me. @{interest_teddie And not even in the more-than-friends sense.|}
                                *goto befriends
                        #I can deal with the attitude if he delivers when it matters.
                                *goto beallies
                        *if ((not (interest_teddie)) and (aro != 4)) #I'd much rather get on his good side. His very good side. @{ftone [Flirt, passive]|}
                            *set interest_teddie true
                            *set flirt_teddie +1
                            Wait.
                            
                            Shit.
                            
                            So [i]that's[/i] why Teddie keeps coming to mind.
                            
                            You—yeah. You don't know what to do with that. @{(brokenheart < 5) Especially when thinking about it evinces a stab of longing in your chest as you're reminded of ${prev_li}.|}
                            *goto walkingon
                        *if (interest_teddie) #I really ought to stop getting so preoccupied about him. @{ftone [Flirt, passive]|}
                            *set flirt_teddie +1
                            *goto distracted           
                            
             #Wil.
                *set whomst 5
                *if ((wimpression = 2) or (wimpression = 3))
                    Wil comes across as the protective type, and you didn't exactly get off on a great foot with ${whim}, what with clashing over Teddie. @{(wimpression = 3)  Despite that, you think you left off in an okay place.|}
                    
                    *if wimpression = 2
                        *choice
                            #I'd like to patch it up with ${whim}. We need to work together.
                                *goto patch
                            #That doesn't matter so long as 'Ghoul' can hold ${whis} own where it counts.
                                *goto beallies
                            *selectable_if (aro != 4) #And I can't stop thinking about ${whim}. [i]Really[/i] thinking about ${whim}. @{ftone [Flirt, passive]|}
                                *set flirt_wil +1
                                *set interest_wil true
                                Wil's been dancing around your head far, far more than ${whe} should.
                    
                                For fuck's sake. You're a disaster.
                                
                                *if (t_wil)
                                    Sleeping on something is supposed to restore clarity, not solidify your terribly-advised attraction.
                                    
                                    *goto walkingon
                                    
                                *else
                                    Clearly the perfect recipe for attraction is to instantly start clashing with someone, and then double down. That makes perfect sense and is in no way primed to explode. @{(brokenheart < 5) You can add the pangs of guilt to the mix for good measure. Just ignoring your feelings for ${prev_li} entirely, aren't you?|}
                                    
                                    Tremendous job, brain. Truly.
                                    *set t_wil true
                                    *goto walkingon
                    *else
                        *goto wilmenu
                *else
                  The first of your fellow recruits. $!{whe} seems to have a decent head on ${whis} shoulders@{(instinctive > 60) . Somebody has to, right?|, which is certainly something you can appreciate.} 
                  
                  Their mask is Ghoul. You wonder where that comes from. Linked to ${whis} powers, maybe? Or perhaps ${whe}'s leaning into the whole goth thing.
                  
                  *label wilmenu
                  @{interest_wil And you're finding yourself dwelling on ${whim} in other ways too.|}
                  *choice
                      #Honestly, I'm really just hoping that ${whe} likes me. @{interest_wil Not even in the more-than-friends sense.|}
                          *goto befriends
                      #@{(wimpression = 3) Regardless of that,|Themed or not, } 'Ghoul' better be able to hold ${whis} own.
                          *goto beallies
                      *if (interest_wil) #For goodness' sake, quit daydreaming! @{ftone [Flirt, passive]|}
                          *set flirt_wil +1
                          You clench your eyes shut and shake your head hard.
                          
                          Unsurprisingly, this does little to shift the thoughts from your mind.
                          
                          Honestly you're not sure what you expected.
                          
                          Chased by Wil-shaped whims, you put your head down and keep walking.
                          *goto walkingon
                      *selectable_if (aro != 4) #Goth, punk, whichever. The ensemble really does something for me. @{ftone [Flirt, passive]|}
                          *set flirt_wil +1
                          *set interest_wil true
                          The thought pops up seemingly out of nowhere, then has the temerity to hang out on the edges of your mind like it's a perfectly innocuous passing whim.
                          
                          Not a chance. You furiously drag the thought from its hiding spot. What do you [i]mean[/i] Wil 'really does something for you'!?
                          
                          @{(expressive < 35) It's such a total blindside that you've even cracked your usually firm composure.|You're absolutely flabbergasted. How out of pocket can you get?}
                          
                          *if brokenheart < 5
                              Frankly, you almost feel sick. Is this what you're like? Are you just going to pretend that ${prev_li} isn't—wasn't—a thing?
                              
                          *else
                              Betrayed by your own brain. Somehow you endeavour to find yet lower depths to sink.
                              
                              
                          Locking up the thought in the dungeon where it belongs, you attempt to recapture your focus.
                          *goto walkingon
         #A member of the Coven.
            Specifically…
            *choice
             #$!{CG}.
                Your favourite drill instructor. Who also happened to get all weird on you yesterday.
                
                Plus, her role as your mission control is now significantly reduced.
                
                @{interest_cg And while one could argue that musing about when next you'll meet is natural under those circumstances, $!{cg}'s on your mind… rather a lot.|}
                *choice
                    #I'm still wondering about that assignment of hers.
                        Hypothesis is breaking several of his own protocols by sending her out and leaving you without a handler.
                        
                        @{(observation >= 35) Can't forget that she was pissed off about it either.|She went all tightlipped about it too.}
                        
                        As always you're in the dark about everything important.
                        *goto walkingon
                    #What was with her anyway?
                        You're struggling for answers there. She's never said anything about feeling responsible for you before.
                        
                        @{cgannoy Maybe she would have elaborated if you hadn't blown her off. Though you can't say you feel bad for it.|Also the part where she completely left you hanging on the conversation. An 'I've said too much' moment if you're ever seen one.}
                        
                        A mentor mystery. You're not sure how you'll get to the bottom of this now.
                        *goto walkingon
                    *if ((aro != 4) and (not (interest_cg))) #It probably doesn't mean anything that I can't get her out of my head, right? @{ftone [Flirt, passive]|}
                        *set interest_cg true
                        *set flirt_cg +1
                        Yeah. Yeah!
                        
                        This is an absolutely normal amount to be thinking about an acquaintance. @{cg_dislike Especially one who is constantly ticking you off.|}
                        
                        Definitely nothing under the surface that you're refusing to acknowledge.
                        *goto walkingon
                    *selectable_if (interest_cg) #Oh no. @{ftone [Flirt, passive]|}
                        *set flirt_cg +1
                        What part of 'into the box that we don't look at' are you failing to grasp here?
                        
                        Why are you like this.
                        *goto walkingon
                        
                    *selectable_if (cgannoy) #I'm regretting fighting with her.
                        *set instinctive %- 7
                        You probably—scratch that, definitely—could have handled the conversation better. $!{cg} was actually opening up the smallest amount, and you slammed the lid straight back down. It felt pretty good in the moment, but on reflection, you might have missed a rare opportunity for some insight into your mentor.
                        
                        Can't be helped now. Maybe you can patch things up next time you see her. Whenever that ends up being.
                        *goto walkingon
                    
             #Hypothesis.
                The man in the chair. The architect of your cage. 
                *choice
                    #What's his angle in all of this?
                        You've never known Hypothesis to be anything but methodical, measuring out each and every step. Though he may experiment, his tests always come with a goal, are backed by a rationale.
                        
                        Alderbrook. The Zone. Your assignment, and the others. He's working towards something, and you don't know what.
                        
                        Yet.
                        *goto walkingon
                    #His voice lingers in my head.
                        [i]Subject exhibits…[/i]
                        
                        [i]…is having a detrimental effect on the subject…[/i]
                        
                        [i]…in all, a promising sign for the subject.[/i]
                        
                        Countless reports and notations. A clinically detached tone. A pencil, scratching its way down page after page.
                        
                        The audio accompaniment for years of suffering.
                        *goto walkingon
             #Catalyst.
                Your pace is slowed by more than a few bruises courtesy of his tender attentions.
                
                *if cattitude = 1
                    Hard to keep him off your mind when your body is still bearing the front.
                    
                *else
                    Payback, you vowed yesterday. Who knows what form it will take, or if it's even possible.
                *choice
                    #I keep expecting him to attack out of nowhere.
                        You're on edge, jumping at shadows. He could be on you at any moment, delivering another trebled beating.
                        
                        Any semblance of calm is impossible.
                        *goto walkingon
                    #Was that screw of his loose before or after the Juice?
                        It's an interesting thought, though not an answer you're ever likely to receive. 
                        
                        *if brutal = 0
                            You don't think you've become more violent, but the contexts of 'before' and 'after' are so utterly divorced it's impossible to say.
                            
                        *else
                            You were pretty violent yourself during the throwdown with the Glory Hounds, but you feel as if you had a better handle on things than you've ever seen from Catalyst.
                            
                        Even so, you won't become another Catalyst. Not ever.
                        *goto walkingon
                    #I'm just non-specifically hating on him.
                        To be fair, he deserves it.
                        
                        @{coven_history And from a distance, in private, you have a little less to fear.|And away from the Coven, the part of you fretting over the tiny rebellion is a little quieter.|Suppressing these feelings has become second nature. It's pure luxury that you don't have to hide them away. For now at least.}
                        *goto walkingon
                            
         #My old friends.
            It's a place your thoughts often drift.
            
            Sometimes you can secret the pain away, walling it up in a part of your mind where you can safely avoid its creeping fingers. 
            
            Those barriers never last.
            
            Then it's back to Prii's smile. Grant's jokes. Shauna's enthusiasm. Even Beth's eyerolling. There's a gaping hole where all of it should be. How were any of you supposed to know what lay in store for you? What happened seems so arbitrary. So unfair.
            
            And you're left to rebuild your wall brick by brick until the next time it collapses.
            *goto walkingon
         #Alistair.
            The man whose first instinct on spotting a vagrant is to make them a home cooked meal.
            
            The man who is big, big trouble.
            
            *if (aliscram)
                You think you did the right thing by sending him away at earliest opportunity. That still may not be enough.
                *choice
                    #And yet, part of me regrets doing it.
                        Isn't that the kicker?
                        
                        There's a laundry list of reasons that your decision was correct, and part of you is still second guessing it.
                        
                        Hopeless. Utterly.
                        *goto walkingon
                    #I need to solve the problem somehow.
                        *set instinctive %- 10
                        Thinking of Alistair as a problem to fix makes the process easier.
                        
                        If only the solving itself was so simple. None of your options are particularly good. Stringing him along is risky. Relocating is impossible. 'Dealing' with him could carry a host of potential consequences, not to mention that you'd be crossing a major line.
                        
                        How do villains even manage this shit?
                        *goto walkingon
                
            *else
                You already let him get too close. You know you did.
                *choice
                    #But it was still nice to talk with him.
                        Isn't that the kicker?
                        
                        There's a whole laundry list of reasons why that was a bad decision, and you went ahead and did it anyway. Boneheaded choices, that's how you roll.
                        
                        You don't regret it. Not for that all-too brief human connection.
                        *goto walkingon
                    #I can't make that mistake twice.
                        Calling Alistair a mistake hurts, but sometimes the truth is painful.
                        
                        You shouldn't have talked to him. There's no changing it now, so all you can do is avoid falling into the same pitfall again.
                        
                        When have you ever, right?
                        *goto walkingon
                    *if (aro != 4) #But I think I'd like to get closer still. Wait. Oh no. @{ftone [Flirt, passive]|}
                        *set interest_alistair true
                        *set flirt_alistair +1
                        
                        Oh no. No. Absolutely not.
                        
                        If there's a single way to make the situation even worse, getting [i]those[/i] kinds of thoughts about him is it.
                        
                        You furiously attempt to shut that nonsense out of your head, and come nothing close to succeeding. 
                        *goto walkingon


*label walkingon
*page_break There are places to be.
The walk takes you over an hour, your thoughts bouncing around your head all the while. Your destination is on a quiet street with just a handful of small houses.

As you glance along the row of buildings, you spot a familiar figure. Dion is standing ramrod straight out on the sidewalk, his arms folded. @{(subterfuge > 33) You think he's trying to be inconspicuous. Trying. It's been a while since you've run across someone acting so jumpy. There's something reassuring in seeing a small glimpse of the person underneath Dion's all-business exterior.|It's little surprising: You'd sort of expected he would stay inside. Dion hanging around like he's meeting up with a friend feels incongruous. }
    
Looking over in your direction, Dion visibly lights up. He seems about to wave, but then catches himself and simply nods instead.

"Good to see you, $!{aka}," he says once you get close. "Come on in. It's just us at the moment; Mallory's off doing something or other. I find it's best not to ask." He's beckoning just-shy of eagerly, and you go ahead and follow him onto the driveway of the closest house.

Dion leads you inside. The interior is a bright and spacious open plan room divided into two distinct areas. A set of fold down wooden stairs descends from the high ceiling, promising a loft space above. The first area is a lounge, with three couches set at right angles to create a cosy little nook. The other is a kitchen, a row of countertops with a gap at its centre providing separation from the lounge. A few doors lead out from the room, which is sparsely decorated, though not as barren as yesterday's spot. 

The space must have been converted from something, but whatever it used to be, it's now the kind of pad you'd have killed to call home back in your barista days.

"You didn't think I'd have us holing up in a barely liveable building, did you?" Dion's beaming with a radiant smile you had no idea he had in him. "Welcome to the real hideout."

*choice
    #"I was expecting a lair. Where are all the elaborate death traps?"
        *set expressive %+ 7
        "Perhaps we'll upgrade to a fortress of evil in time," says Dion. "However, it's generally better to keep a low profile."
        
        *if expressive > 65
            *set rel_architect +1
            "Not even one death trap?" you wheedle.
            
            "None, unless you count the welcome mat we had to put away. Slipping hazard." He looks faintly amused.
            
            You pout. What's the point of being a supervillain if you don't get at least one overly complicated doom device?
            
        *else
            *set rel_architect +2
            You sigh in disappointment. "I suppose you have a point."
            
            "We could always get the welcome mat back out of storage," Dion offers. "That thing is quite the slipping hazard."
            
            "Thanks, but it's not the same," you say mournfully.
            
    #"I have to admit, I'm impressed."
        *set rel_architect +3
        Dion sketches a bow. "I aim to please."
        
        "Consider me pleased. This is a nice place." Sure as hell blows casa del container out of the water.
        
        "Well, we aren't finished quite yet." Dion demurs, but there's no mistaking his delighted expression.
        
        "Looking forward to it then."
        
    #Give him an approving nod.
        *set rel_architect +1
        *set expressive %- 7
        He answers in kind, inclining his head [i]two[/i] fractions of an inch. He really is pleased for you to be here.
        
        Leaning against the nearest wall, you wait for him to go on.
        
    #"It'll do."
        *set rel_architect -2
        "I'd say 'damned by faint praise', but I don't think that even qualifies as praise." He waves a hand dismissively. "No matter." @{(observation > 38) Although he's trying to hide it, he seems a little put out by your lacklustre reaction.|You're not sure how to read that reaction.}
        
        You shrug. It's just a living space. There are more important elements of this team to worry about.
        
        
"Everything's up and running," Dion continues. "Utilities. The fridge is stocked. We have internet." He laughs, rubbing the back of his neck sheepishly. "Of course, what you're not seeing is the part where we ran out of money before we got to the bedrooms and have been crashing on the couches ever since we moved in."

You glance across at the couches, spying a pair of sleeping bags, and take a moment to enjoy the mental image of Mr. Serious Dion tucking up in a camp bed like he's at a sleepover. @{(expressive > 45) "Is this where you tell me you turned to villainy to make rent?"|"I hope your landlord isn't the curious type. They might want to know where the rent is coming from."}

Dion shakes his head. "No rent. I bought the property outright."

While you haven't exactly been keeping up with the housing market these past years, you assume most people still don't have that kind of capital lying around.

It occurs to you that you've got the opportunity to probe Dion for information one-on-one. On the other hand, the more you pry, the sketchier you're going to look.
*choice
    #Quiz him on the finances directly. Nothing ventured, nothing gained.
        *set questions +2
        
        This could be the kind of hint you're after.
        
        "How could you afford that?"
        
        "Housing is surprisingly cheap around here," Dion explains quickly. Too quickly? "Property values tend to take a hit when masks level a couple blocks." 
        
        "I figured that would have rebounded by now," you say, pressing forward.
        
        "A little. My war chest covered it." His eyes focus on you intently. "Alderbrook isn't my first rodeo."
        
        Dangerous waters ahead. You nod and let it drop.
        
    #I'll ask about all the different locations we've met up.
        *set questions +1
        It's a slightly more oblique angle. Hopefully that will throw him off the scent.
        
        "Going back to the barely liveable building for a second, isn't this hideout number three? How did you pull that off?"
        
        "Ah, well." Dion pauses a moment. "The truth is that those safehouses were always intended as temporary. We scouted them out as options for rendezvous points ahead of hitting the loan shark, and simply broke in."
        
        You tilt your head, trying to piece the details together. "The meeting place yesterday was like… furnished though."
        
        Dion nods. "Some aspiring real estate mogul bought up the whole block for refurbishing. Luckily for us, they haven't started viewings yet."
        
        Lucky indeed. If he's telling the truth.
        
    #Best to bide my time. Let the topic pass.
        "That's convenient then," you say, nodding with what you hope reads as satisfaction.
        
        "Just a little less to worry about," Dion agrees.
        
        Other, better opportunities will come.

       
"Anyway, feel free to have a seat while we wait," says Dion, walking over to the couches. He neatly rolls up each sleeping bag in turn, tucking them away behind the furniture, and then gives you an expectant look.

*page_break Sit down.
For the next half hour or so you and Dion simply hang out. He proves to be unexpectedly talkative, albeit not on any topics likely to further your mission. You exchange a little information about each other's powers—apparently he can only manifest his barriers from solid surfaces—discuss the confrontation with the Hounds, and share a couple of Alderbrook anecdotes. The conversation stays away from the personal. Quite the relief.

A brief lull is broken by a sudden clatter at the front door. @{(instinctive > 60) You've sprung to your feet almost before you consciously register the sound,|Your head snaps in that direction,} instantly on full alert.

"Honey I'm home!" sings Mal, framed in the doorway. "Oh hey, $!{aka} too!" They wiggle an arm at you, the closest analogue they have to a wave with an armful of pizza boxes.

"That's what you were doing?" Dion asks. He's looking at you rather than Mallory. Curious. Calculating. @{(instinctive > 60) Abashed, you sit back down.|Your reaction was pretty obvious, you suppose.}

"We're hosting, D," replies Mal, like it's self-evident. They stroll into the kitchen and stack the boxes on a counter. "You are so bad at hospitality."

"I don't see how—"

"$!{aka}, has Dion offered you a drink or anything?"

Your racing heartbeat is calming to more reasonable levels. You shake your head, though it's not like you asked for anything either.

Mal smirks. Dion folds his arms and glares.
*choice
    #"I didn't picture pizza delivery as your side gig, Mal."
        "Oh yeah it's great. I get like a million tips. Probably cause I'm pretty." They put a hand behind their ear, striking a pose. @{interest_wyrd Okay well yeah but—|}
        
        "Or because you're so insufferable, they pay to make you leave faster," says Dion.
        
        Mal lets out an astounded laugh. "Dion that is [i]cutting.[/i] Holy shit."
        
        "Someone has to chop you down to size every so often."
        
        You glance between them both. Mal seems more impressed than upset, and Dion has stopped glaring.
        
    #"You're fine, Dion. I don't need anyone waiting on me."
        *set rel_architect +3
        You get a quick appreciative glance. 
        
        Mal rolls their eyes. "Don't give him excuses, $!{aka}."
        
        You answer with a simple shrug.
        
    #No comment.
        Clearly this is an in-joke of sorts. You'd prefer to leave them to it.
        
        They keep smirking and glaring respectively for a few seconds, and then resume normal operations.
        
Mallory joins you on the sofas, and the shift in dynamic is palpable. Dion speaks much less, content to let Mal talk, which they're more than eager to do, beginning a long and winding tale about their day which is either heavily embellished or the most epic quest for pizza of all time. He breaks in now and then with a sceptical remark or a sly jab, both of which exasperate and entertain Mal in equal measure. For your part, @{(expressive > 60) you can't help from chiming in with the occasional joke or exclamation. What can you say? You're an extrovert.|you stay fairly quiet, nodding along with the story but commenting infrequently. Social situations aren't the easiest environment for you anymore.}

The two of them are clearly friends, sharing an easy patter and perfectly comfortable in one another's company. Inevitably, you're the outsider, constantly hesitating, trailing off at awkward moments, accidentally interrupting. The rhythm of a conversation is just so alien now, and as time passes you @{(expressive > 60) start to speak less and less|fall into almost total silence.}
*temp groupfeel 1
*choice
    #I feel like I'm on the far side of a glass pane.
        Look, but don't touch.
        
        The fragile illusion of normality was shattered the moment another person became involved. You're a marionette, clumsily mimicking the steps to a dance you barely remember.
        
    #It's impossible to relax. I'm a spy.
        *set groupfeel 2
        You have to weigh every word with utmost caution. Place a foot wrong, and you lose everything.
        
        Even if you somehow managed to extricate yourself from your erstwhile teammates' wrath, your only option would be to crawl back to the Coven. To a displeased Hypothesis.
        
        The consequences don't bear thinking about.
        
    #Socialising is a waste of time.
        *set groupfeel 3
        Because…
        *choice
            #What's the point of getting close to people I'm planning to betray?
                You're here for information, not friendship, and these two aren't letting anything slip.
                
            #Aren't we villains? Where's the villainy?
                This is drearily mundane. It's not as if you thought villains were out there criming 24/7, but you're not exactly riveted by Mallory's tale of misplaced toppings and line-cutters.
                

Fortunately, it isn't much longer before there's a knock at the door, which heralds the arrival of Teddie and Kay. Wil follows a few minutes later. Greetings are exchanged and pizza boxes opened, and soon enough, you're all arrayed around the couches, the coffee table in front of you laden with food. More importantly, with six people here you're able to sink into the background while @{groupfeel trying to thaw your numb isolation.|managing your rising anxiety as best as you can.|suppressing your irritation at the delay in getting to business.} You wind up sharing a seat with Wil, who folds ${whis} lanky limbs up to perch like some kind of punk gargoyle. @{interest_wil Casting occasional glances at ${whim} helps to alleviate your ill-feeling a little, though honestly that's just exchanging one problem for another.|$!{whe} thankfully leaves you plenty of personal space.}

The hubbub of so many voices conjures unwelcome echoes. Briefly, your eyes slip closed as the cacophony assails your senses. You force them open again. Not here. Not now.

A diversion. You need one.

*choice
    #Try to read the room.
        Perhaps channelling your energy into people watching will cut through the drone.
        
        *if (observation > 35)
            Shutting out the noise takes effort. Focus. One person at a time. One set of words at a time. That's the way.
            
            The din slowly resolves into actual sentences. Expressions and faces once more begin to make sense.
            
            Kay and Wil are easiest to get a handle on, the former buzzing with nervous energy, the latter projecting calm, but betrayed by darting eyes and a jiggling leg.@{(observation > 50) | Mallory continues to be the boisterous life of the party, contributing considerably to the overall volume of the gathering.} Dion gives more away than you expected, perhaps because you've had longer with him than the others. He's not quite at ease, watching more than speaking. You've never considered him as someone who may lack for confidence.
            
            Teddie's a tougher nut to crack; he's saying little and his face is shifting even less. @{(observation > 50) However, you realise that his eyes keep moving to Kay, depending on his more gregarious friend to carry the conversation. Not sulking, just reserved. Lastly there's Mallory, and though it would be easy to be drawn in by their exuberance, close study reveals a rather different picture.|Just as sullen as ever, you surmise.}
            
            *if observation > 50
                *set archease 1
                *set archinfo +1
                They're playing to the crowd. Drop a one liner or an anecdote, gauge the reaction, adjust accordingly. It's deftly done, and you're only confident in your conclusion after the third subtle switch of tack. In fact, the realisation dawns that more often than not, Dion is specifically watching Mallory's interactions. From the ever-so-slight crease of his brow, he seems to disapprove.
                
                Now that's interesting. The line of leader and subordinate between these two isn't as clear cut as you thought, as if they were once equals. Perhaps they still are.
                
            *else
                You're not sure you can pick out much of anything else. At least you finally feel a little more grounded.
            
        *else
            *set odds +2
            Unfortunately, focus is elusive. Snatches of sentences rise up out of the din, never enough to make proper sense of them, nor draw any proper conclusions. You'll be looking at Kay, but Wil's voice is drowning her out. You try to study Mal, but instead hear Teddie. Too much motion for your eyes. Too much noise for your ears.
            
            All you receive for your efforts is a burgeoning headache. If you can say anything, it's that Mallory is very loud and very boisterous.
            
    #Ride it out.
        *set odds +1
        Venturing outside the bubble will just result in getting battered by the storm.
        
        Best to stay in the eye@{groupfeel , frozen and unfeeling.| and bail out the liferafts, lest apprehension overwhelm you.| and becalm yourself. Frustration is already bubbling. You don't want to capsize in those winds.}
        
        Block out the voices and persevere. Long, slow breaths.
        
        Wil glances over at you and frowns. $!{whe} doesn't say anything, but you feel ${whis} attention on you for some time.
        
    #Saying nothing will look weird. Fake it until I make it.
        *if subterfuge >= 32
            A little misdirection goes a long way. No need to overcompensate.
            
            You re-enter the conversation, sticking to basic small talk. Get someone talking on a topic, and you can often sit back and nod along while making the appropriate noises.
            
            At first, Mallory strikes you as the obvious target for such a ploy; they're already dominating the lion's share of the conversation. However, when you prompt Mal to elaborate on an offhand comment—something about street racing—they shift gears.
                
            "You a driver, $!{aka}? Know much about cars?"
            
            Script flipped. There's a new gleam in their eyes. Interest. Intrigue.
            
            *if subterfuge > 50
                Fortunate, then, that you're sufficiently practiced at lying to land on your feat. "Never got a license," you reply. "That's sort of why they interest me though. All a big mystery."
                
                Mal laughs, their sudden intensity dissipating immediately. "I'll take you for a spin sometime. It's a lot of fun."
                
                @{interest_wyrd They appear to be done scrutinising you, which is just as well with your brain busy tripping over. If you squint, they just suggested going on a date.|The conversation moves on, thankfully sparing you any further scrutiny.}
                
                Mal's certainly no amateur in social chess. Makes you wonder why Dion's leading and they're following. Mal doesn't act like a subordinate; were they equals before Dion took charge? Could they be equals still?
                
                *set archease 1
                *set archinfo +1
            *else
                *set odds +1
                You're unbalanced, and you fumble. "Just thought it was interesting."
                
                "Sure." The gleam goes nowhere. @{interest_wyrd Turns out that Mal's attention is less pleasant when it's packed with scrutiny.|They're seriously scrutinising you now.}
                
                The next few minutes see you under an uncomfortable spotlight. Mal finds a way to deflect every topic in your direction, and you're forced to construct a desperate defence of lies and evasion. The jackass smiles throughout, just in case you had any doubts that they're enjoying subjecting you to the experience.

        *elseif expressive >= 65
            *set odds +2
            You launch yourself back into the conversation with the exuberance of a particularly friendly husky, and then promptly slam into a brick wall. Heads turn, brows are furrowed, and askance looks are given as you make yourself loud and proud.
            
            Problem is, you're forcing it. Outgoing as you are, your energy is fuelled by genuine enthusiasm. @{groupfeel Struggling to feel anything at all|On edge already|Pushing through irritation}, you realise that you're overcompensating. Shortly after everyone else came to the same conclusion.
            
            Once again you recede to the fringes, but the damage is already done.
            
        *else
            *set odds +2
            A good plan with the modest flaw that you aren't a particularly good liar.
            
            Your efforts to blend into the conversation are about as successful as hiding an eighteen wheeler behind a SUV. If you thought you were having trouble with just Dion and Mal, your struggles are amplified tenfold when it's an entire group. Each fumbled segue or awkward laugh earns you another askance look from one of your companions, and the more you try to compensate, the more obvious it is that you're forcing it.
            
            By the time you slink back to the fringes, the damage is already done.

*page_break "A moment, everyone."
The assembled group falls silent as Dion rises. His eyes sweep across you and the others. "Now that we're all here and settled, let's discuss our next steps." Everything about Dion's demeanour has shifted. He's Architect now, even without his costume. "First, though, allow me to officially welcome you all. From here on out, you're Altruists."

He lets that sit for a moment.

The Altruists, huh?
*set teamdisplay 2
*fake_choice
    #I like it.
        A label to bring some swagger to any crime spree. It's provocative, and deliberately so.
        
        You're looking forward to leaving your first calling card. $!{mask}, of the Altruists.
        
    #Sounds worryingly ideological.
        That's the kind of label someone assumes when they genuinely believe they're in the right. And back in the day, there were some seriously crackpot villains who believed they were in the right.
        
        You really hope that you're not about to be on the frontlines of some crusade.
        
        *if motive = 1
            Then again maybe you should have anticipated this, given Dion's reaction to your anti-establishment claims. Not that seeing it coming would have changed your mission.
        
    #Interesting name for a gang of villains.
        Labels carry a lot of weight in the parahuman world. While you've heard of teams both heroic and villainous with odd, quirky, or just plain unsuiting names, most groups take the opportunity to put their branding on their sleeves. Literally, in a few cases.
        
        Picking a name like that is a mission statement from Dion. He's not the type to throw a dart at the board.
        
        
Wil lifts a hand, spreading ${whis} fingers wide. "Before we go any further, I'd like to know what you're about. Or what we're about, I guess. I don't like being in the dark about why I'm risking my ass." Kay and Teddie both nod agreement. You keep your face still and neutral.

"I can't say. Not yet," Dion answers. "Understand that trust goes both ways. I need to know that you're committed." He folds his arms. "Once I'm satisfied, I'll tell you everything. You have my word."

Wil makes a face, but then sighs. "Wouldn't normally take that for an answer, but you came through with the files. Don't try and string us along."

Dion inclines his head. A fraction of an inch. "Understood."

You suppose it was too much to hope that Dion would have his motives drawn up in a neat pamphlet.
*page_break

"You mentioned our next steps," you prompt Dion.

"Right, thank you, $!{aka}," he replies, and then returns to the group as a whole. "As a new team, it's important that we hit the ground running. Fortunately, an opportunity has fallen in our lap."

"Remember that errand yesterday?" Mal addresses you and the others, but doesn't wait for a response. "Me and D met up with the Businessmen. They've got info we need, you see." Mal raises a warning finger. "The info is part of the everything Dion mentioned. So don't ask."

"Urgh." Kay wrinkles her nose. "Those guys run half the drugs and protection rackets in town. We're working with them?"

You can understand her distaste. The Businessmen paint a veneer of respectability over their activities, but in truth they're little more than a mafia, ruthlessly exploiting anyone and everyone they can to insinuate their fingers into as many pies as possible. All in the name of maximising their profits. In $!{cg}'s briefing, she reserved her most scathing critiques for them. 
*choice
    #I share in Kay's discomfort.
        The Businessmen hurt ordinary people on a daily basis. While you're not so naive as to believe the Altruists aren't going to harm anyone, there's a distinction between wrecking a loan shark and systematically sapping the life out of the vulnerable and defenceless in the pursuit of lining their pockets.
        
        @{(brutal > 0) You keep your ruthless streak to combat, where it belongs.|You're all too aware of how many thin and fragile lines can be crossed.}
        
    #It doesn't matter to me.
        Calling yourself Altruists isn't going to keep your hands any cleaner. The underworld is filled with unsavoury characters, and the parahuman underworld even moreso.
        
        If you baulk every time you rub shoulders with the immoral, you aren't going to get far in this line of work. @{(brutal > 0) Why else would you fight the way that you do?|You need to be mentally fortified for the day you have to pull the metaphorical trigger.}
        
    *selectable_if (motive =3) #Regardless of my own opinion, I should remember I said I was in this for the money.
        The $!{aka} who's all about money would be indifferent to the Businessmen, and that's the person everyone here needs to see.
        
        Keep the mask firmly in place. Always.
        

No need to voice any of that. You say nothing.

"It's an exchange, not a collaboration." Dion tells Kay. 

She doesn't look particularly swayed by the semantic distinction.  "Then what are we trading?"

"They offered us the choice of two favours. Acting as enforcers, and a smash and grab." One corner of his mouth twitches upward. "We're doing both."

A miniature ripple goes around the seated group, save Mal.
*choice
    #Question what that does for us.
        You're missing the thread here. That's twice the henchmanning for the same reward.
        
        *if coven_history = 1
            *goto falter
        
        *else
            You quietly clear your throat, attracting Dion's attention. "How does that help?" You ask.
            
            "Both jobs benefit us. Enforcing demonstrates that we can handle ourselves. As for the theft, nothing says that we can't steal more than we're asked to take. It'll be a good way to raise some funds."
        
            "Businessmen are real precious about etiquette or whatever," Mal adds. "If they complain about us going over and above, they're hurting their own rep."
        
            "Finally, it's an avenue for us to make our mark. Fending off the Glory Hounds has drawn plenty of eyes. Pulling off two hits at once will ensure that we're the talk of the town." Dion concludes the one-two punch. Dion and Mal have a tendency to do that with their explanations, you note.
        
            "Hopefully for the right reasons," Wil murmurs.
        
            It was your question, so Dion's looking to you for acknowledgement.
            *choice
                #"So it's a flex? I'm down."
                    *set instinctive %+ 10
                    *set rel_wyrd -3
                    Mallory smirks. "Yeah, you could call it that."
                    
                    Dion @{(instinctive < 40) arches an eyebrow. "I didn't expect you to view it that way,|sighs in resignation. "I can see I'll have my hands full with you,} $!{aka}."
                    
                    @{(instinctive < 40) "I just appreciate a good flex is all," you say quickly.|"I promise only to flex on the bad guys. Good guys? Whichever," you reply.}
                    
                    "Not flexing anything with arms like those," Teddie says snippily. You wince. @{(mc_exbuild = 6) Considering how built you used to be, your gauntness is a real sore spot.|Can count on Teddie to cut you off at the knees.}
                    
                    "Teddie…" Kay murmurs. Teddie seems very faintly abashed, and looks away.
                    
                    Meanwhile, Dion moves on.
                    
                #"This seems risky."
                    *set instinctive %- 10
                    *set rel_wyrd +3
                    "It's calculated," Dion and Mallory say at the same time, earning the latter a very annoyed look from the former. Dion pauses, continuing when Mal remains silent, albeit grinning. "Six of us is enough firepower that we can afford to divide our forces now and then."
                
                    "For our first mission?" you ask.
                
                    "$!{aka}, I could pull off this heist all by myself," Mal drawls. "You're worrying too much."
                
                    "Mallory exaggerates," says Dion—'no I don't' Mal mouths at the group—"But I would be reluctant to send the whole team to either job in the first place. Too much attention."
                
                    "Mm," you say neutrally. At least they've thought it through.
                    
                    Dion seems content to leave it there, and moves on.
                #"You're the boss."
                    As neutral a response as it gets. Usually a safe option.
                
                    Dion appears unbothered by the fence-sitting, and moves on.
             
    #Question what that does for us. Belligerently.
        You don't see how acting as henchmen for other villains is supposed to get your team established.
        
        *if coven_history = 1
            *label falter
            Opening your mouth to object, your voice falters in your throat.
            
            So easily you forget the consequences for speaking out of turn.
            
            [i]One two three. One two three. One two three.[/i]
            
            You realise you're trembling. Casting a surreptitious glance around the couches, you conclude that thankfully, nobody seems to have noticed. Looking at the ring of faces helps ground you, reminds you that this isn't the Coven. Dion's not going to hit you.
            
            Right?
            
            By the time you've regrouped, Dion's already moving on.
            
        
        *else   
         "So not only are we doing their dirty work, we're doubling it?"
   
         "Means to an end, $!{aka}," Mal chips in. "Quickest way to get them to spill."
        
         You shake your head. "I can accept that for one job, not two."
        
         "It's a calculated risk," says Dion. "We drew a lot of eyes by fending off the Glory Hounds. Pulling off two hits at the same time will ensure we're the talk of the town."
         *choice
            #Keep pushing. There's something under this.
                *set questions +2
                 
                "Why does that matter?" Your tone is blunt. "We're boosting a rival for the sake of a few headlines."
                
                Dion hesitates, and that's when you see it.
                
                Subtly, his eyes flick to Mal, and Mal jumps in.
                
                "Don't underestimate the value of headlines, $!{aka}. Remember that we're the new kids in town. If we want to get our foot in the door, we need to build up our reputation."
                
                Dion nods, and then glances at you. 
                
                "Okay, I get it," you say nonchalantly, because you just got your tell.
                
                *if (archease =1)
                    Dion deferring to Mallory. It confirms your suspicions; Dion isn't used to being the guy in charge.
                
                *else
                    *set archease 1
                    *set archinfo +1
                    Dion deferred to Mallory. That's not leader and subordinate behaviour. At some stage, those two were on the same level. Perhaps they still are.
                    
                As you chew that over, Dion moves on.
                    
            #Accept the explanation.
                *set questions +1
                "Alright. I guess I see it," you reply.
                
                "Hope it's the right kind of attention," Wil murmurs. "We bungle our first mission and we're a laughing stock."
                
                "We're in jail," Teddie counters bluntly.
                
                "Hey hey hey, it's bad luck to talk about failure," Mal interjects with a broad wink. "Worrying over worst case scenarios is a self-fulfilling prophecy, you know?"
                
                Dion clears his throat pointedly, cutting through the chatter to signal it's time to move on.
        
    #He's going somewhere with this. Wait.
        "Pulling off two jobs at once will give us a reputational boost, not to mention that we can take extra items from the theft in order to raise funds."
        
        "Yeah, I'd really like an actual bed," says Mal. They pause, seeing the incredulous looks on the others' faces. "What? I'm not kidding. Those couch springs are destroying my back."
        
        Dion clears his throat pointedly, signalling his intent to move on.


"We'll split into two groups of three," he says. "I'll take Mallory and $!{wname} for the smash and grab. $!{aka}, you'll lead the enforcing team."

Wait. What?
*temp outer false
*choice
    #"Me!?"
        *set outer true
        It bursts out involuntarily.
        
        *if expressive < 30
            Mallory barely attempts to muffle a gleeful laugh.
            
            "Not so stoic now, huh?"
            
        *else
            Mallory grins. You think you see a smile ghost across Dion's face.
            
            
        "S-Sorry, I just—" you stammer, attempting to regain your composure. "You caught me off guard," you conclude lamely.
        
        *label onearth
        What on earth is Dion thinking? He barely knows you.
        
    #"Sure, I've got this." Though this is unexpected, I'm confident.
        Yeah. Yeah, okay. You can handle being in charge.
        
        *if coven_history = 3
            You've spent far too long forced to lick the Coven's collective boot. It'll be a breath of fresh air to be the one giving the orders.
            
            Just have to pull together all that leadership experience you don't have.
            
            Ah. Hm.
            
        *else
            It isn't as if you've been under the Coven's boot for half a decade, @{(coven_history = 1) desperately obeying their every command.|obeying because it's all you know.}
            
            You're set up absolutely perfectly to assume a leadership role.
            
            Fuck.
    #"Sure, I've got this." Oh fuck, oh fuck, oh fuck.
        *set odds +1
        In charge. You. In charge.
        
        There's absolutely no way that this can go wrong. It's not as if you've spent a half decade @{coven_history getting deference beaten into you,|obeying because it's all you know,|suppressing any hint of independent thought,} right?
        
        Fuck.
    #Nod stoically.
        *if expressive > 65
            *set odds +1
            As a notably stoic individual, you're immediately betrayed by your jitters.
            
            Mal grins.
            *set outer true
            
        *elseif expressive > 40
            *set odds +1
            You make your best effort to keep it cool while you nod, though you feel enough jitters that you're doubtful you pulled it off.
            
            Mal grins.
            *set outer true
            
        *else
            As calm and collected as ever, you let the instruction roll right off of you.
            
            Doesn't mean your mind isn't going a hundred miles an hour though.
            
            *goto onearth
    #Nod, because I'm too shocked to speak.
        This… was not on your bingo card.
        
        Is Dion trying to fake you out? Demonstrating a hitherto unseen mischievous streak?
        
        No, he's not the type.
        
        What.

Heedless of your inner@{outer —and outer—| }turmoil, Dion continues speaking. "I need Mallory with me, and you have experience in powered engagements."

One whole brawl's worth of it.

Besides, what's so essential about Mallory? Their durability doesn't seem like a linchpin power for a thieving job. @{(archease =1) Maybe Dion isn't confident without Mal at their side. It'd fit with some of what you've been piecing together.|}

"You didn't say what we're actually doing." Teddie states.

"A few of the lower profile local heroes banded together recently and disrupted one of the Businessmen's fronts. We're to be the reprisal by way of a beatdown," explains Dion.

Kay shifts. "I think I heard about those guys. Ranger partnered with Mis/Hit, right?"

Dion nods. "Correct. It shouldn't be too much of a challenge. Ranger is all enthusiasm and little skill, while Mis and Hit have very narrow powersets."

"Beat the Businessmen," Teddie points out. "Can't be worthless."
*temp thescene false
*choice
    #I'm falling behind. I ask about the unfamiliar names.
        *temp thescene true
        $!{cg} could hardly give you the rundown on every last hero in the city. You're at a bit of a disadvantage. Especially after Dion's bombshell.
        
        "Can someone catch me up on who they all are?" you ask. Since you're claiming to be fresh on the scene, nobody should cross-examine the question.
        
        "Sure," says Kay. Her tone is bright, but her volume measured. Weird. "Mis/Hit are a duo. They've been a thing for a couple of years, mostly they do hit and runs on the Shreds. Mis can dodge. Y'know, 'miss'. Hit is perfectly accurate. Ranger calls himself 'the protector of the Parks'…" she hesitates. "I think he does camouflage? Honestly you usually only hear about him getting his butt kicked."
        
    #It doesn't matter who they are. We'll win.
        *set rel_kay +2
        Perhaps Dion's bombshell has you unbalanced, but that doesn't mean you're completely rattled.
        
        @{(expressive > 30) "Don't worry, we'll kick their asses."|"We'll crush them."}
        
        Teddie grunts noncommittally. 
        
        "Heck yeah we will." Kay bounces in place, quite at odds with her voice's measured volume.
        
    #Nod in agreement with Teddie.
        *set rel_teddie +2
        His eyes flick over to you for an instant.
        
        "True," says Dion. "Still, they weren't fighting parahuman opposition."
        
Mal smirks. "The mighty Businessmen getting punked out by a rookie team. Bet that stings."

"They're used to dealing with independents, I bet," says Wil. "Three masks is more firepower than your average hired goon can handle."

"Are there many hero teams around here?" you ask.
*choice
    #@{thescene The question's a natural extension, and it|This type of question} fits my cover. 
        It's important to have your secret—one of them, anyway—close to the front of your mind. @{(motive = 3) Mask on. Always|}
        
    #Knowing our enemy helps preparation.
        *set instinctive %- 5
        There are a lot of angles to cover in mask combat. @{(fighting_style = 2) More information, better strategy.|}
        
    #I'm just curious! Not everything is a scheme.
        *set instinctive %+ 5
        Sometimes a question is simply a question.
               
"Not particularly," Dion replies. "The DPR makes it a bureaucratic nightmare to get licensed for a team outside their jurisdiction. Most Alderbrook heroes stick to solo work and hope to catch the eye of an established group."

You nod understanding. "So these guys are kind of upstarts."

"Correct. As Mallory said, it's quite damaging for the Businessmen to lose to a group like them."

"We're just roughing them up, right?" Wil asks. Dion nods, and ${whe} breathes a sigh of relief, before glancing over at you. "Better you than me, $!{aka}. I don't think I could bring myself to hurt Ranger. It'd be like dropkicking a puppy."
*temp bevillain false
*choice
    #"You know him?" I thought Wil wasn't involved in mask business.
        *set rel_wil + 3
        Wil shakes ${whis} head. "Seen a few videos online. He's always spouting justice this and righteousness that, then getting clowned on." Wil shrugs. "I'm surprised Mis/Hit took him seriously enough to team up."
        
        "He tries hard," says Kay.
        
        "Participation trophy hero." Teddie's tone is acid. Both Mallory and Wil laugh, and he looks surprised.
        
    #"Don't tell me you're squeamish." We're villains, aren't we? 
        *temp bevillain true
        *set rel_wyrd -2
        *set rel_teddie + 3
        Wil frowns. "I'm not it's just—" $!{whe} stops and draws a sharp breath. "I didn't sign up to be a hitman, that's all."
        
        You shrug. Sometimes this isn't going to be clean or pretty. You're prepared to do what needs to be done.
      
        "Well, you only gotta hit [i]man[/i]," says Kay, grinning.
        
        Wil groans. "Forget beating them up. Puns like that, they'll surrender just to make it stop."
        
    #"Puppy dropkicking is Wednesdays."
        *if expressive < 30
            *set rel_wil +3
            *set rel_wyrd +5
            *set rel_kay +3
            *set rel_teddie +6
            Your tone is deadpan, your poker face flawless.
            
            Wil locks up, unable to tell that you're joking. Mal survives for a few seconds, but then cracks and begins laughing. Wil gratefully follows their lead. Kay grins, and you think you see a momentary half-smile on Teddie's face.
            
            "I actually thought you were serious for a second," Wil says, once ${whis} chuckles are under control.
            
        *else
            *set rel_wil +4
            *set rel_wyrd +4
            *set rel_kay +4
            *set rel_teddie +2
            A little grin curls onto your face. Wil and Mallory both laugh, and you get a grin from Kay too.
            
        
"Oh, yeah," says Mal, drawing themself up from their casual slouch. "On that point. The murdery point, I mean. You can hurt these guys, but don't kill 'em. Like. Seriously don't. Killing folks is how you get the heroes to take off the kid gloves and believe me, if someone like a Surpass quits pulling their punches, you are not getting back up."

That kills the smiles stone dead. Pun intended.

Surprisingly, it's Teddie that breaks the silence. "It's fighting. With superpowers. Shit's going to happen." He crosses his arms, staring Mallory down in challenge.

"Collateral damage may sometimes be unavoidable," Dion interjects. "However, villains who make a habit of using lethal force on civilians or heroes tend to get trapped in a cycle of escalation." He meets Teddie's eyes, and then sweeps his gaze across the rest of the group. "If you absolutely must kill, then so be it. Just remember that it's a line that you can't uncross."

@{(observation > 50) Something twitches in Mallory's face. They [i]really[/i] didn't like that. Everyone else's|Everyone's} expression is solemn.

Teddie grunts. "Fine."

Killing… you've dwelt plenty on the topic. @{arcade_civvy Heck, if Arcade's lasers had been a little to one side back at the loan shark, you'd already have that bystander's blood on your hands.|}
*choice
    #@{arcade_civvy Despite that, |}I want to avoid killing anyone as best I can.
        You wouldn't have chosen this life.
        
        What you can choose is whether to let yourself become the monster your powers want you to be. @{arcade_civvy The near-miss with the laser, maybe that's a lesson on how easily you can slip.|Slipping would be so easy.} @{bevillain Perhaps your comment to Wil just now was just bravado.|}
        
        Already, you barely recognise the person in the mirror. You don't want to lose what little of yourself you have left.
        
    #I won't set out to cause a massacre, but if some people die, that's the way it is.
        *set killthink 2
        You're slinging superpowers around. It's unlikely that nobody gets caught in the firing line, and if they do that isn't really your problem. Should have kept their head down.
        
        If you lose a fight, you're done. You can't afford to hold back, not even for your morals.
        
        *goto monster
    #I have no compunctions about killing.
        *set killthink 3
        Honestly, it's something you've been mentally preparing for since the beginning.
        
        Mal and Dion tried to make it sound scary, but capture is already a death sentence, so what difference does it make if the heroes start gunning for you in retaliation? There's no incentive whatsoever for you not to use every tool in your arsenal to the fullest, no matter the lethality.
        
        *label monster
        You're a monster. May as well @{(killthink =3) embrace|act like} it.


"On that cheerful note…" Wil's forcing a smile. "When do we get started?"

"If we're all amenable, I had this evening in mind," Dion replies.

So soon? He sure doesn't waste time.
*choice
    #Question him. I want to see how he explains.
        *set questions +1
        *set rel_teddie +2
        *set rel_wyrd -2
        No information without investigation, and that's the objective. @{coven_history You can do this. You can. It's just one question.||}
        
        "Isn't that a little rushed?" Opposite you, Teddie nods.
        
        "Right?" chips in Mal. "I wanted to catch the game tonight."
        
        Dion ignores them. "We have to strike while the iron is hot, or the Businessmen will try to shift the terms."
        
        Damn. That's actually a perfectly reasonable explanation. This one's a bust. You nod and try not to make a face.
        
    #Guess I'd better kick my fighting brain into gear.
        *set rel_architect +2
        You slowly flex your fists, beginning to centre yourself. @{fighting_style You'll need to get warmed up, run through some exercises to ensure you're limber for what's to come. Can't go pulling a muscle trying to throw an elbow or a knee.|You have to engage those thinking muscles, and doubly so now that your strategies have two extra people to incorporate. Teamwork. There's a new one.|There are a bunch of exercises you like to run through with your powers, ensuring that they're malleable and ready to work in whichever manner you need.|}
        
        Alright. Alright. Let's get into the zone.
        
        Dion's gaze alights on you. There's subtle approval in the glance.
        
    #Quietly freak out.
        *set odds +1
        *set rel_kay +1
        *set rel_wil +2
        You had a full week to psych yourself up for the last scrap. Now you have to get prepped in a matter of hours?
        
        That's— cool cool cool cool. No problems here. You're doing totally fine with this new information. Ignore the shaking that just happens sometimes with this model.
        
        Unfortunately, Wil hasn't read the manual, and leans in closer. @{t_wil Great. As if this could get any worse.|} "Hey," ${whe} murmurs. "Don't worry. It'll be fine."
        
        Kay also shoots you a smile, and with it comes the horrible awareness that the whole team saw this little episode.
        
        You fix your gaze somewhere high on a wall, and wait for them to move on.

Abruptly, Teddie stands up. "If it's today, I need to get ready."

"You're welcome to stay—" Dion begins, but Teddie cuts him off.

"No."

Kay springs up too. "I should grab some things!"

"Alright," Dion looks over. "$!{wname}? $!{aka}?"

Wil shrugs. "I'll stick around."

As for you…
*fake_choice
    #I want breathing space, but it's impractical to walk halfway across town.
        That claustrophobic feeling is back, an echo of the Coven.
        
        Unfortunately facts are facts and distance is distance. The trek to your hideout and back would leave you barely any time to actually prepare. You're stuck here for now.
        
    #It's smarter to stay close.
        Why go wandering off when the assignment is right here? 
        
    #Here's as good as anywhere.
        Makes no difference to you.
        
"I'll stay too," you say. "Anywhere for me to prep?"

Mal nods, jabbing a thumb over their shoulder. "Room right there is empty. Have fun!"

"Let's reconvene at four pm," says Dion. "$!{aka}, it would be best for you to go out to meet Kay and Teddie at a safe distance when the time comes. Their powers are conspicuous."

Teddie glowers. Kay drops her eyes to the floor. The subsequent exchange of goodbyes is rather muted. As they head out, you make a swift exit next door.

The new room is indeed bare, but it's clean, reasonably airy, and has more than enough floor space for you to do your thing. You shrug off your satchel, shuck your jacket, and after a brief consideration, shed your shirt too. Long sleeves get in the way, and a ragged tanktop preserves your modesty.

*page_break Get to stretching.
*temp shirtless 1

You allow your mind to disengage as you go through the familiar motions. Nothing too strenuous. You're readying your body for the coming exertions, not working out. Loose and limber, that's the way.

It's soothing not to think. For a little while, you can be on your own island. Your physical form and nothing else. No plots and schemes, no secrets, no agendas.

Such moments never last.

Your flow is interrupted by a knock at the door. "Coming in!" calls Mal.

*choice
    #Scramble for my shirt.
        You dive for your t-shirt and force it over your head. The sleeves wind up in a terrible tangle, and it clings horribly to your sweaty body, but you're clothed.
        
    #Scramble for my shirt, but fumble it.
        *set shirtless 2
        You dive for your t-shirt, but as you try desperately to get it on, your head winds up in an arm hole, the other sleeve completely inside out. You have to take it back off to extricate yourself, and by then it's too late.
        
    #I don't care.
        *set shirtless 3
        You're not nude.
    
In Mallory strolls. "Just wanted to—heyy there." Their eyes widen, and are then promptly averted. Doesn't stop you from seeing the grin tugging at their mouth.
*temp walkin 1
*choice
    #Ask bluntly what they want.
        "What is it?" you snap.
        
        "If this is a bad time, I can come back—"
        
        "Spit it out already!"
        
    *selectable_if (shirtless != 2) #@{shirtless Play it|There exists no way on earth that I can play this|Play it} cool.
        *set walkin 2
        "Yeah?" you ask.
        
        Your casual tone seems to disarm Mallory.

        "Well, uh… you know, if this is a bad time, I can come back," they waffle.
        
        "No, no, say what you were going to say." @{shirtless |You adjust your sleeves, trying to tweak them back into something resembling order.|You stare directly at Mal's averted face, maintaining your blasé vibe.}
        
    *selectable_if (shirtless != 3) #I am drowning in molten embarrassment.
        *set walkin 3
        Your face goes supernova. @{(mc_skintone > 3) You think your blush might light up the entire room.|Even with your dark skin, you think they might feel the heat from there.}
        
        "If this is a bad time, I can come back—"
        
        "Just spit it out already!" You were shooting for firm. It winds up as a squeak.
        
        They stifle a laugh. Cool great fantastic, can you die maybe immediately?
        
        
@{walkin They're completely unabashed. "Just|"Right. Uh…|"I} wanted to let you know that I grabbed a few spare clothes earlier@{mc_height |, they'll probably be a little big on you, but they're there| | |, they might be a little small on you, but they're there|, they'll probably be small on you, but they're there} if you need to change."

Mal finally glances back in your direction. Their grin is sly@{walkin .|, confidence already restored.|.} "Looks like you kinda got started on that already, huh?"

@{walkin "Congrats: you have eyes," you don't quite growl.|You shrug. "I was stretching. It's important."|You squirm. "That's not what I—it's a workout."}

@{walkin They touch two fingers to their eyelids. "That I do. Anyway,|They laugh softly. "Very practical. Anyway,|A faint trace of guilt breaks through Mal's smirk. "Hey, look,} I'm sorry for barging in. I hate to make anyone uncomfortable." Their contrition survives for about two seconds before they add. "Especially someone as cute as you."

And there they go again.
*temp pretend false
*choice
    #Accept the apology. Ignore the flirtatious overture.
        *label apology
        "I appreciate the apology," you say. @{pretend There. That should be enough.|You're just not going to touch the rest.}
        
        "Sure thing," they reply, unfazed by your non-reaction.
        
        *goto anythingelse
    *selectable_if (aro != 4) #Accept the apology. Pretend to ignore the flirtatious overture. @{ftone [Flirt, passive]|}
        *set flirt_wyrd +1
        *set pretend true
        @{interest_wyrd Darn it. They're infuriatingly under your skin.|Reluctantly, you have to admit that something about Mal is pushing a button or two.}
        *set interest_wyrd true
        
        *goto apology
    #Change the subject.
        "Thanks for the clothes," you say. "I'll check them out if I need to."
        
        Mal raises an eyebrow, recognising your deflection, but choosing not to comment. "Yeah, no worries."
        
        *label anythingelse
        "Was there anything else?" @{walkin ||You're still melting alive, and you know you can't sound nearly as casual as you'd ilke.}
        
        "Nah, that'll about do it."
        
        You nod, and Mal takes the hint.
        
        *goto maloutie
    #Make it clear I have no interest in Mal. [Block romance/flirting.]
        *set romance_wyrd 1
        *set interest_wyrd false
        *set flirt_wyrd 0
        "Could you give the flirting a rest? I'm not interested," you say, folding your arms.
        
        "Gotcha." Mal raises their hands, palms flat. "Won't happen again."
        
        You nod acknowledgement.
        
        *goto maloutie
    *selectable_if (aro = 4) #Tell them plainly that I'm not into this kind of thing.
        *set romance_wyrd 1
        "I'm ace and aromantic," you say. "I'd appreciate if you stopped."
        
        Mal's eyebrows rise. "Shoot really?" They grimace. "That is absolutely my bad. Won't happen again."
        
        You nod acknowledgement.
        
        *goto maloutie
    *selectable_if ((aro != 4) and (walkin = 3)) #I'm debilitatingly flustered, and can muster no coherent response. @{ftone [Flirt, passive]|}
        *set flirt_wyrd +1
        *set interest_wyrd true
        "Great!" you manage. It's unclear what you're responding to. You sure as hell don't know. "I—yeah!"
        
        As embarrassing moments go, this one's a chart topper.
        
        Mal's content to watch you flounder for a while. Maybe even raise the temperature a couple of degrees. "Some of those words form a sentence," they observe. "Maybe not in that order."
        
        Demon. You glare at them helplessly, feeling @{(shirtless =1) exposed despite successfully reclothing.|horribly exposed.}
        
        "Sorry," they say, neither looking nor sounding apologetic. "I'll leave you alone."
        
        "Thanks—I mean, good!" Why. Why. Why. Mal's grinning from ear to ear.
        
        *goto maloutie
    *selectable_if (aro != 4) #Clam up. @{ftone [Flirt, passive]|}
        *set flirt_wyrd +1
        *set interest_wyrd true
        …
        
        Well, at least if you keep your mouth shut you can't say anything stupid.
        
        The integrity of this strategy is challenged as Mal just watches you, smile inching wider and wider. @{walkin You meet their eyes stubbornly.|You meet their eyes levelly.|Meeting their eyes is outright impossible.}
        
        Eventually, they seem satisfied, stepping back with a nonchalant shrug.
        
        *goto maloutie
    
    *selectable_if (aro != 4) #Two can play at this game! @{ftone [Flirt]|}
        *set flirt_wyrd +1
        *set interest_wyrd true
        *set overt_wyrd true
        "I don't mind," you say, @{(walkin = 2) shrugging nonchalantly.|despite evidence to the contrary.} "Not when it's someone as cute as [i]you[/i]." @{walkin ||Your voice wobbles a little on the delivery. At least you didn't stammer.}
        
        Mal's eyebrows shoot up, but they recover almost instantly. "Good to know," they purr.
        
        You fold your arms and give them a look of challenge@{walkin .|.|, pretending your face isn't continuing to heat the entire building.} Mal returns your gaze, eyes half-lidded, and then steps back with a shrug that's trying a little too hard to be nonchalant.
        
        *goto maloutie
    *selectable_if ((aro != 4) and (shirtless != 1)) #If they're going to stare, I'll give them a view. @{ftone [Flirt]|}
        *set flirt_wyrd +1
        *set interest_wyrd true
        *set overt_wyrd true
        *if feature = 4
            You [i]start[/i] to make a show of shrugging, spreading your arms a little wider than necessary. Then your tanktop begins to ride up, brushing against the scarification upon your stomach.
            
            That brings you crashing to earth in a hurry. You snatch your top back into place, hoping that Mal didn't see anything. They seem more fixed on your arms, the sweat glueing the vest to your skin, but you can't be sure.
            
            Stupid. Stupid.
            
        *else
            You make a show of shrugging, spreading your arms a little wider than necessary. Your tanktop rises, exposing a little of your midriff; though honestly with the sweat glueing the vest to your skin, it's not leaving much to the imagination anyway. @{walkin ||You pretend your face isn't continuing to heat the entire building.}
        
            Mal's suddenly lost for words, blinking rapidly. Funny how that works.
        
        
        "Anything else?" you ask, @{walkin casual as you can muster.|casual as you can muster.|very nearly sounding casual.}
        
        Their eyes travel down your body, and then flick back up to your face. The grin's back in full force. "I guess not."
        
        You nod@{walkin .|.|, barely clinging to your composure.}
        
        *goto maloutie

*label maloutie
"Catch you later." They sweep their hands out as they bow, and then head for the door.

*if (interest_wyrd)
    Mal pauses in the doorway, throwing back a glance. "Keep working up that sweat!" They wink, and are gone.
    
    *if (brokenheart < 5)
        Your heart twinges longingly, and any joy leeches away in an instant. @{brokenheart Beth would never have said something like that.|Prii might have said something like that if sufficiently provoked.|Shauna would have imploded if she ever said something like that.|You could just imagine Grant making that kind of quip.|}
        
        You miss @{brokenheart her.|them.|her.|him.|DUMMY}
    
*elseif ((shirtless != 1) and (feature = 3))
    Mal pauses in the doorway, throwing back a glance. "Cool tattoos by the way." They slip out.
    
    What? Oh fuck. You touch a hand to either shoulder, grimacing. The fucking markings. You didn't even think about them.
    
    Another complication for the pile.
    
*else
    They're gone a moment later.
    
*page_break
*if ((shirtless != 1) and (feature > 2))
    *set featseen_wyrd true
    
Thankfully for your blood pressure, you're left alone for the next couple of hours. @{walkin ||Finally you can drag yourself out of the pit of humiliation lava.}

Not much in the mood to socialise, you stay in the room, completing the odd set of exercises and shoring up your mental state as best you can. Panic, and you're in serious trouble.

The appointed hour rolls around and feeling about as ready as you can be, you head back into the hideout proper. Mallory is sprawled across one of the couches, chatting idly with Wil. $!{whe}'s morphed into Ghoul since you saw ${whim} last, the lower part of ${whis} face covered by a half mask with a gnashing teeth design and ${whis} body concealed by a tattered cloak. With ribbons of black cloth hanging all around ${whim}, shifting with every movement, it renders Ghoul's true silhouette impossible to see.

Dion stands off by himself, helmet tucked under one arm. He beckons you over.

"You have the location?"

He texted you the relevant details already. You nod.

*if ((questions > 1) and (odds > 1))
    Architect studies you for a moment. "It's interesting to see how you act with the rest of the group."
    
    *label loaded
    Interesting. Never has a word felt more loaded.
    *label deflecthim
    *choice
        #Bluff my way out of trouble.
            *if subterfuge > 50
                *if ((questions > 1) and (odds < 2))
                    "What can I say? @{(expressive >= 50) I'm a talkative kind of ${mc_guy}."|I might be quiet a lot of the time, but I speak up when it counts."} You give him your most guileless smile.
                    
                    Architect hesitates for a moment too long. "I see."
                    
                *else
                    "Interesting is definitely one of the nicer things anyone's said about me," you feign an apologetic shrug. "Sorry if I was disruptive."
                    
                    Architect takes a moment too long to shake his head. "No, no. It's not a problem."
                    
                You nod easily, willing your pounding heart to still.
            
                *goto getgoing
            *else
                 "That's me," you say, trying on a guileless smile for size and finding it to be less of a fit than you'd like.
                 
                 Architect's silent regard seems to last an eternity. "Mm."
                 
                 Shit.
                 
                 *if ((questions > 1) and (odds > 1))
                     *set doubt_architect +15
                     
                 *else
                     *set doubt_architect + 10
                
                "Anyway…" you say, hunting for the conversation's eject button.
                
                *goto getgoing
        #He's fishing for a reaction. I won't give him one.
            Instead you simply nod and keep your mouth shut.
            
            Architect's silent regard seems to last an eternity. You match silence with silence.
            
            When he finally breaks his gaze, you're left with the nagging feeling he still got what he was after.
            
            *if ((questions > 1) and (odds > 1))
                *set doubt_architect +10
                
            *else
                *set doubt_architect +5
                
            *goto getgoing    
*elseif (questions > 1)
    Architect studies you for a moment. "You were quite vocal while we planned."
    
    Which means you said too much. Dammit.
    *goto deflecthim
*elseif (odds > 1)
    Architect studies you for a moment. "You're an interesting one, $!{aka}."
    
    *goto loaded
*else
    "And do you feel prepared?"
    *choice
        #"I do."
            Ready as you'll ever be, you suppose.
            
        #"I do." I don't.
            But you're not going to tell him that.
            
        #"Guess we'll see."
            You won't know until you're in the thick of things.

    *label getgoing
    Architect nods, and then checks his watch. "You should be going." 

    Back into the fray. You feel a restless stirring from within. Your body knows it's almost time.
    
    You head for the exit.
    
*page_break His voice catches you in the door.
"$!{mask}. Don't let me down."

[i]"You little prick," Catalyst snarls, a trail of your saliva dripping down his face.[/i]
    
[i]"Eat shit," you croak. One eye is swollen shut and you can barely lift your head. Desperate defiance is all you've got.[/i]
    
[i]Then he smiles. And that's so, so much worse than anger. "Fine. If you're gonna be a defective little letdown, it's back downstairs." He grabs you by the hair and starts dragging.[/i]
    
[i]It's far too late to beg.[/i]
    
"$!{aka}?" Dion's voice dredges you up from the depths. "Are you alright?"

You cling to the doorframe. It might be the only thing holding you up.

"Can count on me," you mutter hoarsely.
*page_break Stumble outside.
You don't know if Dion speaks further, but he doesn't follow.

The ghosts dog your heels as you head for the rendezvous point.
*choice
    #So much for my mentality.
        At this rate you're not even going to be able to take care of yourself, much less direct the others.
        
        A couple of hours to yourself doesn't begin to mend this damage. You don't know that anything can.
        
    #I'll try to get my head back in the game.
        You're not there anymore. You're not.
        
        Concentrate on the real, $!{forename}.
        
    #Now Architect is going to think I'm a liability. Great.
        How the hell are you supposed to build up your credibility with episodes like that hitting you out of nowhere?
        
        Forget saying the wrong thing or failing to line up a lie, you might just blow your cover by existing.
        

With deep breaths, you push the echoes to the furthest corners you can manage and keep moving.
*finish
    